with System; use System;
with System.Storage_Elements; use System.Storage_Elements;
with Unchecked_Conversion;
package body Interfaces.C.Strings is
function To_chars_ptr is
new Unchecked_Conversion (Address, chars_ptr);
function To_Address is
new Unchecked_Conversion (chars_ptr, Address);
function Peek (From : chars_ptr) return char;
pragma Inline (Peek);
procedure Poke (Value : char; Into : chars_ptr);
pragma Inline (Poke);
function "+" (Left : chars_ptr; Right : size_t) return chars_ptr;
pragma Inline ("+");
function Position_Of_Nul (Into : char_array) return size_t;
function Memory_Alloc (Size : size_t) return chars_ptr;
pragma Import (C, Memory_Alloc, "__gnat_malloc");
procedure Memory_Free (Address : chars_ptr);
pragma Import (C, Memory_Free, "__gnat_free");
function "+" (Left : chars_ptr; Right : size_t) return chars_ptr is
begin
return To_chars_ptr (To_Address (Left) + Storage_Offset (Right));
end "+";
procedure Free (Item : in out chars_ptr) is
begin
if Item = Null_Ptr then
return;
end if;
Memory_Free (Item);
Item := Null_Ptr;
end Free;
function New_Char_Array (Chars : char_array) return chars_ptr is
Index : size_t;
Pointer : chars_ptr;
begin
Index := Position_Of_Nul (Into => Chars);
Pointer := Memory_Alloc ((Index - Chars'First + 1));
if Index <= Chars'Last then
Update (Item => Pointer,
Offset => 0,
Chars => Chars (Chars'First .. Index),
Check => False);
else
Update (Item => Pointer,
Offset => 0,
Chars => Chars,
Check => False);
Poke (nul, into => Pointer + size_t'(Chars'Length));
end if;
return Pointer;
end New_Char_Array;
function New_String (Str : String) return chars_ptr is
begin
return New_Char_Array (To_C (Str));
end New_String;
function Peek (From : chars_ptr) return char is
begin
return char (From.all);
end Peek;
procedure Poke (Value : char; Into : chars_ptr) is
begin
Into.all := Character (Value);
end Poke;
function Position_Of_Nul (Into : char_array) return size_t is
begin
for J in Into'Range loop
if Into (J) = nul then
return J;
end if;
end loop;
return Into'Last + 1;
end Position_Of_Nul;
function Strlen (Item : chars_ptr) return size_t is
Item_Index : size_t := 0;
begin
if Item = Null_Ptr then
raise Dereference_Error;
end if;
loop
if Peek (Item + Item_Index) = nul then
return Item_Index;
end if;
Item_Index := Item_Index + 1;
end loop;
end Strlen;
function To_Chars_Ptr
(Item : char_array_access;
Nul_Check : Boolean := False) return chars_ptr
is
begin
if Item = null then
return Null_Ptr;
elsif Nul_Check
and then Position_Of_Nul (Into => Item.all) > Item'Last
then
raise Terminator_Error;
else
return To_chars_ptr (Item (Item'First)'Address);
end if;
end To_Chars_Ptr;
procedure Update
(Item : chars_ptr;
Offset : size_t;
Chars : char_array;
Check : Boolean := True)
is
Index : chars_ptr := Item + Offset;
begin
if Check and then Offset + Chars'Length > Strlen (Item) then
raise Update_Error;
end if;
for J in Chars'Range loop
Poke (Chars (J), Into => Index);
Index := Index + size_t'(1);
end loop;
end Update;
procedure Update
(Item : chars_ptr;
Offset : size_t;
Str : String;
Check : Boolean := True)
is
begin
Update (Item, Offset, To_C (Str, Append_Nul => False), Check);
end Update;
function Value (Item : chars_ptr) return char_array is
Result : char_array (0 .. Strlen (Item));
begin
if Item = Null_Ptr then
raise Dereference_Error;
end if;
for J in Result'Range loop
Result (J) := Peek (Item + J);
end loop;
return Result;
end Value;
function Value
(Item : chars_ptr;
Length : size_t) return char_array
is
begin
if Item = Null_Ptr then
raise Dereference_Error;
end if;
if Length = 0 then
raise Constraint_Error;
end if;
declare
Result : char_array (0 .. Length - 1);
begin
for J in Result'Range loop
Result (J) := Peek (Item + J);
if Result (J) = nul then
return Result (0 .. J);
end if;
end loop;
return Result;
end;
end Value;
function Value (Item : chars_ptr) return String is
begin
return To_Ada (Value (Item));
end Value;
function Value (Item : chars_ptr; Length : size_t) return String is
Result : char_array (0 .. Length);
begin
if Item = Null_Ptr then
raise Dereference_Error;
end if;
for J in 0 .. Length - 1 loop
Result (J) := Peek (Item + J);
if Result (J) = nul then
return To_Ada (Result (0 .. J));
end if;
end loop;
Result (Length) := nul;
return To_Ada (Result);
end Value;
end Interfaces.C.Strings;