AC_DEFUN([_NCN_TOOL_PREFIXES],
[ncn_tool_prefix=
test -n "$host_alias" && ncn_tool_prefix=$host_alias-
ncn_target_tool_prefix=
test -n "$target_alias" && ncn_target_tool_prefix=$target_alias-
]) []
AC_DEFUN([NCN_CHECK_TARGET_TOOL],
[AC_REQUIRE([_NCN_TOOL_PREFIXES]) []if test -n "$ncn_target_tool_prefix"; then
AC_CHECK_PROG([$1], [${ncn_target_tool_prefix}$2],
[${ncn_target_tool_prefix}$2], , [$4])
fi
if test -z "$ac_cv_prog_$1" ; then
ncn_cv_$1=$$1
AC_CHECK_PROG([ncn_cv_$1], [$2], [$2], [$3], [$4])
$1=$ncn_cv_$1
else
$1="$ac_cv_prog_$1"
fi
]) []
AC_DEFUN([NCN_STRICT_CHECK_TOOL],
[AC_REQUIRE([_NCN_TOOL_PREFIXES]) []if test -n "$ncn_tool_prefix"; then
AC_CHECK_PROG([$1], [${ncn_tool_prefix}$2],
[${ncn_tool_prefix}$2], , [$4])
fi
if test -z "$ac_cv_prog_$1" ; then
if test $build = $host ; then
ncn_cv_$1=$$1
AC_CHECK_PROG([ncn_cv_$1], [$2], [$2], [ifelse([$3],[],[$2],[$3])], [$4])
$1=$ncn_cv_$1
else
$1="ifelse([$3],[],[${ncn_tool_prefix}$2],[$3])"
fi
else
$1="$ac_cv_prog_$1"
fi
]) []
AC_DEFUN([NCN_STRICT_CHECK_TARGET_TOOL],
[AC_REQUIRE([_NCN_TOOL_PREFIXES]) []if test -n "$ncn_target_tool_prefix"; then
AC_CHECK_PROG([$1], [${ncn_target_tool_prefix}$2],
[${ncn_target_tool_prefix}$2], , [$4])
fi
if test -z "$ac_cv_prog_$1" ; then
if test $build = $target ; then
ncn_cv_$1=$$1
AC_CHECK_PROG([ncn_cv_$1], [$2], [$2], [ifelse([$3],[],[$2],[$3])], [$4])
$1=$ncn_cv_$1
else
$1="ifelse([$3],[],[${ncn_target_tool_prefix}$2],[$3])"
fi
else
$1="$ac_cv_prog_$1"
fi
]) []