(defconst xml-undefined-entity "?"
"What to substitute for undefined entities")
(defvar xml-entity-alist
'(("lt" . "<")
("gt" . ">")
("apos" . "'")
("quot" . "\"")
("amp" . "&"))
"The defined entities. Entities are added to this when the DTD is parsed.")
(defvar xml-sub-parser nil
"Dynamically set this to a non-nil value if you want to parse an XML fragment.")
(defvar xml-validating-parser nil
"Set to non-nil to get validity checking.")
(defsubst xml-node-name (node)
"Return the tag associated with NODE.
Without namespace-aware parsing, the tag is a symbol.
With namespace-aware parsing, the tag is a cons of a string
representing the uri of the namespace with the local name of the
tag. For example,
<foo>
would be represented by
'(\"\" . \"foo\")."
(car node))
(defsubst xml-node-attributes (node)
"Return the list of attributes of NODE.
The list can be nil."
(nth 1 node))
(defsubst xml-node-children (node)
"Return the list of children of NODE.
This is a list of nodes, and it can be nil."
(cddr node))
(defun xml-get-children (node child-name)
"Return the children of NODE whose tag is CHILD-NAME.
CHILD-NAME should match the value returned by `xml-node-name'."
(let ((match ()))
(dolist (child (xml-node-children node))
(if (and (listp child)
(equal (xml-node-name child) child-name))
(push child match)))
(nreverse match)))
(defun xml-get-attribute-or-nil (node attribute)
"Get from NODE the value of ATTRIBUTE.
Return nil if the attribute was not found.
See also `xml-get-attribute'."
(cdr (assoc attribute (xml-node-attributes node))))
(defsubst xml-get-attribute (node attribute)
"Get from NODE the value of ATTRIBUTE.
An empty string is returned if the attribute was not found.
See also `xml-get-attribute-or-nil'."
(or (xml-get-attribute-or-nil node attribute) ""))
(defun xml-parse-file (file &optional parse-dtd parse-ns)
"Parse the well-formed XML file FILE.
If FILE is already visited, use its buffer and don't kill it.
Returns the top node with all its children.
If PARSE-DTD is non-nil, the DTD is parsed rather than skipped.
If PARSE-NS is non-nil, then QNAMES are expanded."
(if (get-file-buffer file)
(with-current-buffer (get-file-buffer file)
(save-excursion
(xml-parse-region (point-min)
(point-max)
(current-buffer)
parse-dtd parse-ns)))
(with-temp-buffer
(insert-file-contents file)
(xml-parse-region (point-min)
(point-max)
(current-buffer)
parse-dtd parse-ns))))
(defvar xml-name-re)
(defvar xml-entity-value-re)
(defvar xml-att-def-re)
(let* ((start-chars (concat "[:alpha:]:_"))
(name-chars (concat "-[:digit:]." start-chars))
(whitespace "[ \t\n\r]"))
(defvar xml-name-start-char-re (concat "[" start-chars "]"))
(defvar xml-name-char-re (concat "[" name-chars "]"))
(defvar xml-name-re (concat xml-name-start-char-re xml-name-char-re "*"))
(defvar xml-names-re (concat xml-name-re "\\(?: " xml-name-re "\\)*"))
(defvar xml-nmtoken-re (concat xml-name-char-re "+"))
(defvar xml-nmtokens-re (concat xml-nmtoken-re "\\(?: " xml-name-re "\\)*"))
(defvar xml-char-ref-re "\\(?:&#[0-9]+;\\|&#x[0-9a-fA-F]+;\\)")
(defvar xml-entity-ref (concat "&" xml-name-re ";"))
(defvar xml-pe-reference-re (concat "%" xml-name-re ";"))
(defvar xml-reference-re (concat "\\(?:" xml-entity-ref "\\|" xml-char-ref-re "\\)"))
(defvar xml-att-value-re (concat "\\(?:\"\\(?:[^&\"]\\|" xml-reference-re "\\)*\"\\|"
"'\\(?:[^&']\\|" xml-reference-re "\\)*'\\)"))
(defvar xml-tokenized-type-re "\\(?:ID\\|IDREF\\|IDREFS\\|ENTITY\\|ENTITIES\\|NMTOKEN\\|NMTOKENS\\)")
(defvar xml-notation-type-re (concat "\\(?:NOTATION" whitespace "(" whitespace "*" xml-name-re
"\\(?:" whitespace "*|" whitespace "*" xml-name-re "\\)*" whitespace "*)\\)"))
(defvar xml-enumeration-re (concat "\\(?:(" whitespace "*" xml-nmtoken-re
"\\(?:" whitespace "*|" whitespace "*" xml-nmtoken-re "\\)*"
whitespace ")\\)"))
(defvar xml-enumerated-type-re (concat "\\(?:" xml-notation-type-re "\\|" xml-enumeration-re "\\)"))
(defvar xml-att-type-re (concat "\\(?:CDATA\\|" xml-tokenized-type-re "\\|" xml-notation-type-re"\\|" xml-enumerated-type-re "\\)"))
(defvar xml-default-decl-re (concat "\\(?:#REQUIRED\\|#IMPLIED\\|\\(?:#FIXED" whitespace "\\)*" xml-att-value-re "\\)"))
(defvar xml-att-def-re (concat "\\(?:" whitespace "*" xml-name-re
whitespace "*" xml-att-type-re
whitespace "*" xml-default-decl-re "\\)"))
(defvar xml-entity-value-re (concat "\\(?:\"\\(?:[^%&\"]\\|" xml-pe-reference-re
"\\|" xml-reference-re "\\)*\"\\|'\\(?:[^%&']\\|"
xml-pe-reference-re "\\|" xml-reference-re "\\)*'\\)")))
(defvar xml-syntax-table
(let ((table (make-syntax-table)))
(dotimes (c 31)
(modify-syntax-entry c "." table)) (dolist (c '(?\t ?\n ?\r)) (modify-syntax-entry c " " table))
(modify-syntax-entry ?\" "\"" table)
(modify-syntax-entry ?' "\"" table)
(modify-syntax-entry ?. "_" table)
(modify-syntax-entry ?: "_" table)
(unless (featurep 'xemacs)
(dolist (c '(#x00B7 #x02D0 #x02D1 #x0387 #x0640 #x0E46 #x0EC6 #x3005
#x3031 #x3032 #x3033 #x3034 #x3035 #x309D #x309E #x30FC
#x30FD #x30FE))
(modify-syntax-entry (decode-char 'ucs c) "w" table)))
table)
"Syntax table used by `xml-parse-region'.")
(eval-and-compile
(defconst xml-name-regexp "[[:alpha:]_:][[:alnum:]._:-]*"))
(defun xml-parse-region (beg end &optional buffer parse-dtd parse-ns)
"Parse the region from BEG to END in BUFFER.
If BUFFER is nil, it defaults to the current buffer.
Returns the XML list for the region, or raises an error if the region
is not well-formed XML.
If PARSE-DTD is non-nil, the DTD is parsed rather than skipped,
and returned as the first element of the list.
If PARSE-NS is non-nil, then QNAMES are expanded."
(with-syntax-table (standard-syntax-table)
(let ((case-fold-search nil) xml result dtd)
(save-excursion
(if buffer
(set-buffer buffer))
(save-restriction
(narrow-to-region beg end)
(goto-char (point-min))
(while (not (eobp))
(if (search-forward "<" nil t)
(progn
(forward-char -1)
(setq result (xml-parse-tag parse-dtd parse-ns))
(if (and xml result (not xml-sub-parser))
(error "XML: (Not Well-Formed) Only one root tag allowed")
(cond
((null result))
((and (listp (car result))
parse-dtd)
(setq dtd (car result))
(if (cdr result) (add-to-list 'xml (cdr result))))
(t
(add-to-list 'xml result)))))
(goto-char (point-max))))
(if parse-dtd
(cons dtd (nreverse xml))
(nreverse xml)))))))
(defun xml-maybe-do-ns (name default xml-ns)
"Perform any namespace expansion.
NAME is the name to perform the expansion on.
DEFAULT is the default namespace. XML-NS is a cons of namespace
names to uris. When namespace-aware parsing is off, then XML-NS
is nil.
During namespace-aware parsing, any name without a namespace is
put into the namespace identified by DEFAULT. nil is used to
specify that the name shouldn't be given a namespace."
(if (consp xml-ns)
(let* ((nsp (string-match ":" name))
(lname (if nsp (substring name (match-end 0)) name))
(prefix (if nsp (substring name 0 (match-beginning 0)) default))
(special (and (string-equal lname "xmlns") (not prefix)))
(ns (or (cdr (assoc (if special "xmlns" prefix)
xml-ns))
"")))
(cons ns (if special "" lname)))
(intern name)))
(defun xml-parse-fragment (&optional parse-dtd parse-ns)
"Parse xml-like fragments."
(let ((xml-sub-parser t)
children)
(while (not (eobp))
(let ((bit (xml-parse-tag
parse-dtd parse-ns)))
(if children
(setq children (append (list bit) children))
(if (stringp bit)
(setq children (list bit))
(setq children bit)))))
(reverse children)))
(defun xml-parse-tag (&optional parse-dtd parse-ns)
"Parse the tag at point.
If PARSE-DTD is non-nil, the DTD of the document, if any, is parsed and
returned as the first element in the list.
If PARSE-NS is non-nil, then QNAMES are expanded.
Returns one of:
- a list : the matching node
- nil : the point is not looking at a tag.
- a pair : the first element is the DTD, the second is the node."
(let ((xml-validating-parser (or parse-dtd xml-validating-parser))
(xml-ns (if (consp parse-ns)
parse-ns
(if parse-ns
(list
(cons "" "")
(cons "xml" "http://www.w3.org/XML/1998/namespace")
(cons "xmlns" "http://www.w3.org/2000/xmlns/"))))))
(cond
((looking-at "<\\?")
(search-forward "?>")
(skip-syntax-forward " ")
(xml-parse-tag parse-dtd xml-ns))
((looking-at "<!\\[CDATA\\[")
(let ((pos (match-end 0)))
(unless (search-forward "]]>" nil t)
(error "XML: (Not Well Formed) CDATA section does not end anywhere in the document"))
(concat
(buffer-substring-no-properties pos (match-beginning 0))
(xml-parse-string))))
((looking-at "<!DOCTYPE")
(let ((dtd (xml-parse-dtd parse-ns)))
(skip-syntax-forward " ")
(if xml-validating-parser
(cons dtd (xml-parse-tag nil xml-ns))
(xml-parse-tag nil xml-ns))))
((looking-at "<!--")
(search-forward "-->")
nil)
((looking-at "</")
'())
((looking-at "<\\([^/>[:space:]]+\\)")
(goto-char (match-end 1))
(let* ((node-name (match-string-no-properties 1))
(attrs (xml-parse-attlist xml-ns))
children pos)
(when (consp xml-ns)
(dolist (attr attrs)
(when (and (consp (car attr))
(equal "http://www.w3.org/2000/xmlns/"
(caar attr)))
(push (cons (cdar attr) (cdr attr))
xml-ns))))
(setq children (list attrs (xml-maybe-do-ns node-name "" xml-ns)))
(if (looking-at "/>")
(progn
(forward-char 2)
(nreverse children))
(if (eq (char-after) ?>)
(progn
(forward-char 1)
(let ((end (concat "</" node-name "\\s-*>")))
(while (not (looking-at end))
(cond
((looking-at "</")
(error "XML: (Not Well-Formed) Invalid end tag (expecting %s) at pos %d"
node-name (point)))
((= (char-after) ?<)
(let ((tag (xml-parse-tag nil xml-ns)))
(when tag
(push tag children))))
(t
(let ((expansion (xml-parse-string)))
(setq children
(if (stringp expansion)
(if (stringp (car children))
(setq children (append (list (concat (car children) expansion))
(cdr children)))
(setq children (append (list expansion) children)))
(setq children (append expansion children))))))))
(goto-char (match-end 0))
(nreverse children)))
(error "XML: (Well-Formed) Couldn't parse tag: %s"
(buffer-substring-no-properties (- (point) 10) (+ (point) 1)))))))
(t (unless xml-sub-parser (error "XML: (Well-Formed) Invalid character"))
(xml-parse-string)))))
(defun xml-parse-string ()
"Parse the next whatever. Could be a string, or an element."
(let* ((pos (point))
(string (progn (if (search-forward "<" nil t)
(forward-char -1)
(goto-char (point-max)))
(buffer-substring-no-properties pos (point)))))
(setq pos 0)
(while (string-match "\r\n?" string pos)
(setq string (replace-match "\n" t t string))
(setq pos (1+ (match-beginning 0))))
(xml-substitute-special string)))
(defun xml-parse-attlist (&optional xml-ns)
"Return the attribute-list after point.
Leave point at the first non-blank character after the tag."
(let ((attlist ())
end-pos name)
(skip-syntax-forward " ")
(while (looking-at (eval-when-compile
(concat "\\(" xml-name-regexp "\\)\\s-*=\\s-*")))
(setq end-pos (match-end 0))
(setq name (xml-maybe-do-ns (match-string-no-properties 1) nil xml-ns))
(goto-char end-pos)
(if (looking-at "\"\\([^\"]*\\)\"")
(setq end-pos (match-end 0))
(if (looking-at "'\\([^']*\\)'")
(setq end-pos (match-end 0))
(error "XML: (Not Well-Formed) Attribute values must be given between quotes")))
(if (assoc name attlist)
(error "XML: (Not Well-Formed) Each attribute must be unique within an element"))
(let ((string (match-string-no-properties 1))
(pos 0))
(replace-regexp-in-string "\\s-\\{2,\\}" " " string)
(let ((expansion (xml-substitute-special string)))
(unless (stringp expansion)
(error "XML: (Not Well-Formed) Entities in attributes cannot expand into elements"))
(push (cons name expansion) attlist)))
(goto-char end-pos)
(skip-syntax-forward " "))
(nreverse attlist)))
(defun xml-skip-dtd ()
"Skip the DTD at point.
This follows the rule [28] in the XML specifications."
(let ((xml-validating-parser nil))
(xml-parse-dtd)))
(defun xml-parse-dtd (&optional parse-ns)
"Parse the DTD at point."
(forward-char (eval-when-compile (length "<!DOCTYPE")))
(skip-syntax-forward " ")
(if (and (looking-at ">")
xml-validating-parser)
(error "XML: (Validity) Invalid DTD (expecting name of the document)"))
(looking-at xml-name-regexp)
(let ((dtd (list (match-string-no-properties 0) 'dtd))
type element end-pos)
(goto-char (match-end 0))
(skip-syntax-forward " ")
(cond ((looking-at "PUBLIC\\s-+")
(goto-char (match-end 0))
(unless (or (re-search-forward
"\\=\"\\([[:space:][:alnum:]-'()+,./:=?;!*#@$_%]*\\)\""
nil t)
(re-search-forward
"\\='\\([[:space:][:alnum:]-()+,./:=?;!*#@$_%]*\\)'"
nil t))
(error "XML: Missing Public ID"))
(let ((pubid (match-string-no-properties 1)))
(skip-syntax-forward " ")
(unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
(re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
(error "XML: Missing System ID"))
(push (list pubid (match-string-no-properties 1) 'public) dtd)))
((looking-at "SYSTEM\\s-+")
(goto-char (match-end 0))
(unless (or (re-search-forward "\\='\\([^']*\\)'" nil t)
(re-search-forward "\\=\"\\([^\"]*\\)\"" nil t))
(error "XML: Missing System ID"))
(push (list (match-string-no-properties 1) 'system) dtd)))
(skip-syntax-forward " ")
(if (eq ?> (char-after))
(forward-char)
(if (not (eq (char-after) ?\[))
(error "XML: Bad DTD")
(forward-char)
(while (not (looking-at "\\s-*\\]"))
(skip-syntax-forward " ")
(cond
((looking-at
"<!ELEMENT\\s-+\\([[:alnum:].%;]+\\)\\s-+\\([^>]+\\)>")
(setq element (match-string-no-properties 1)
type (match-string-no-properties 2))
(setq end-pos (match-end 0))
(cond
((string-match "^EMPTY[ \t\n\r]*$" type) (setq type 'empty))
((string-match "^ANY[ \t\n\r]*$" type) (setq type 'any))
((string-match "^(\\(.*\\))[ \t\n\r]*$" type) (setq type (xml-parse-elem-type (match-string-no-properties 1 type))))
((string-match "^%[^;]+;[ \t\n\r]*$" type) nil)
(t
(if xml-validating-parser
(error "XML: (Validity) Invalid element type in the DTD"))))
(if (and (assoc element dtd)
xml-validating-parser)
(error "XML: (Validity) Element declarations must be unique in a DTD (<%s>)"
element))
(push (list element type) dtd)
(goto-char end-pos))
((looking-at (concat "<!ATTLIST[ \t\n\r]*\\(" xml-name-re
"\\)[ \t\n\r]*\\(" xml-att-def-re
"\\)*[ \t\n\r]*>"))
(goto-char (match-end 0)))
((looking-at "<!--")
(search-forward "-->"))
((looking-at (concat "<!ENTITY[ \t\n\r]*\\(" xml-name-re
"\\)[ \t\n\r]*\\(" xml-entity-value-re
"\\)[ \t\n\r]*>"))
(let ((name (match-string-no-properties 1))
(value (substring (match-string-no-properties 2) 1
(- (length (match-string-no-properties 2)) 1))))
(goto-char (match-end 0))
(setq xml-entity-alist
(append xml-entity-alist
(list (cons name
(with-temp-buffer
(insert value)
(goto-char (point-min))
(xml-parse-fragment
xml-validating-parser
parse-ns))))))))
((or (looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
"\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
"\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
(looking-at (concat "<!ENTITY[ \t\n\r]+\\(" xml-name-re
"\\)[ \t\n\r]+PUBLIC[ \t\n\r]+"
"\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
"\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'"
"[ \t\n\r]+\\(\"[^\"]*\"\\|'[^']*'\\)"
"[ \t\n\r]*>")))
(let ((name (match-string-no-properties 1))
(file (substring (match-string-no-properties 2) 1
(- (length (match-string-no-properties 2)) 1))))
(goto-char (match-end 0))
(setq xml-entity-alist
(append xml-entity-alist
(list (cons name (with-temp-buffer
(insert-file-contents file)
(goto-char (point-min))
(xml-parse-fragment
xml-validating-parser
parse-ns))))))))
((or (looking-at (concat "<!ENTITY[ \t\n\r]+%[ \t\n\r]+\\(" xml-name-re
"\\)[ \t\n\r]+SYSTEM[ \t\n\r]+"
"\\(\"[^\"]*\"\\|'[^']*'\\)[ \t\n\r]*>"))
(looking-at (concat "<!ENTITY[ \t\n\r]+"
"%[ \t\n\r]+"
"\\(" xml-name-re "\\)[ \t\n\r]+"
"PUBLIC[ \t\n\r]+"
"\\(\"[- \r\na-zA-Z0-9'()+,./:=?;!*#@$_%]*\""
"\\|'[- \r\na-zA-Z0-9()+,./:=?;!*#@$_%]*'\\)[ \t\n\r]+"
"\\(\"[^\"]+\"\\|'[^']+'\\)"
"[ \t\n\r]*>")))
(goto-char (match-end 0)))
((looking-at (concat "%" xml-name-re ";"))
(goto-char (match-end 0)))
(t
(when xml-validating-parser
(error "XML: (Validity) Invalid DTD item"))))))
(if (looking-at "\\s-*]>")
(goto-char (match-end 0))))
(nreverse dtd)))
(defun xml-parse-elem-type (string)
"Convert element type STRING into a Lisp structure."
(let (elem modifier)
(if (string-match "(\\([^)]+\\))\\([+*?]?\\)" string)
(progn
(setq elem (match-string-no-properties 1 string)
modifier (match-string-no-properties 2 string))
(if (string-match "|" elem)
(setq elem (cons 'choice
(mapcar 'xml-parse-elem-type
(split-string elem "|"))))
(if (string-match "," elem)
(setq elem (cons 'seq
(mapcar 'xml-parse-elem-type
(split-string elem ",")))))))
(if (string-match "[ \t\n\r]*\\([^+*?]+\\)\\([+*?]?\\)" string)
(setq elem (match-string-no-properties 1 string)
modifier (match-string-no-properties 2 string))))
(if (and (stringp elem) (string= elem "#PCDATA"))
(setq elem 'pcdata))
(cond
((string= modifier "+")
(list '+ elem))
((string= modifier "*")
(list '* elem))
((string= modifier "?")
(list '\? elem))
(t
elem))))
(defun xml-substitute-special (string)
"Return STRING, after subsituting entity references."
(let ((point 0)
children end-point)
(while (string-match "&\\([^;]*\\);" string point)
(setq end-point (match-end 0))
(let* ((this-part (match-string-no-properties 1 string))
(prev-part (substring string point (match-beginning 0)))
(entity (assoc this-part xml-entity-alist))
(expansion
(cond ((string-match "#\\([0-9]+\\)" this-part)
(let ((c (decode-char
'ucs
(string-to-number (match-string-no-properties 1 this-part)))))
(if c (string c))))
((string-match "#x\\([[:xdigit:]]+\\)" this-part)
(let ((c (decode-char
'ucs
(string-to-number (match-string-no-properties 1 this-part) 16))))
(if c (string c))))
(entity
(cdr entity))
((eq (length this-part) 0)
(error "XML: (Not Well-Formed) No entity given"))
(t
(if xml-validating-parser
(error "XML: (Validity) Undefined entity `%s'"
this-part)
xml-undefined-entity)))))
(cond ((null children)
(setq children
(concat prev-part expansion)))
((stringp children)
(if (stringp expansion)
(setq children (concat children prev-part expansion))
(setq children (list expansion (concat prev-part children)))))
((and (stringp expansion)
(stringp (car children)))
(setcar children (concat prev-part expansion (car children))))
((stringp expansion)
(setq children (append (concat prev-part expansion)
children)))
((stringp (car children))
(setcar children (concat (car children) prev-part))
(setq children (append expansion children)))
(t
(setq children (list expansion
prev-part
children))))
(setq point end-point)))
(cond ((stringp children)
(concat children (substring string point)))
((stringp (car (last children)))
(concat (car (last children)) (substring string point)))
((null children)
string)
(t
(concat (mapconcat 'identity
(nreverse children)
"")
(substring string point))))))
(defun xml-debug-print (xml &optional indent-string)
"Outputs the XML in the current buffer.
XML can be a tree or a list of nodes.
The first line is indented with the optional INDENT-STRING."
(setq indent-string (or indent-string ""))
(dolist (node xml)
(xml-debug-print-internal node indent-string)))
(defalias 'xml-print 'xml-debug-print)
(defun xml-debug-print-internal (xml indent-string)
"Outputs the XML tree in the current buffer.
The first line is indented with INDENT-STRING."
(let ((tree xml)
attlist)
(insert indent-string ?< (symbol-name (xml-node-name tree)))
(setq attlist (xml-node-attributes tree))
(while attlist
(insert ?\ (symbol-name (caar attlist)) "=\"" (cdar attlist) ?\")
(setq attlist (cdr attlist)))
(setq tree (xml-node-children tree))
(if (null tree)
(insert ?/ ?>)
(insert ?>)
;; output the children
(dolist (node tree)
(cond
((listp node)
(insert ?\n)
(xml-debug-print-internal node (concat indent-string " ")))
((stringp node) (insert node))
(t
(error "Invalid XML tree"))))
(when (not (and (null (cdr tree))
(stringp (car tree))))
(insert ?\n indent-string))
(insert ?< ?/ (symbol-name (xml-node-name xml)) ?>))))
(provide 'xml)
;; arch-tag: 5864b283-5a68-4b59-a20d-36a72b353b9b
;;; xml.el ends here