(defface button '((((type pc) (class color))
(:foreground "lightblue"))
(((supports :underline t)) :underline t)
(t (:foreground "lightblue")))
"Default face used for buttons."
:group 'basic-faces)
(defvar button-map
(let ((map (make-sparse-keymap)))
(define-key map "\r" 'push-button)
(define-key map [mouse-2] 'push-button)
map)
"Keymap used by buttons.")
(defvar button-buffer-map
(let ((map (make-sparse-keymap)))
(define-key map [?\t] 'forward-button)
(define-key map "\e\t" 'backward-button)
(define-key map [backtab] 'backward-button)
map)
"Keymap useful for buffers containing buttons.
Mode-specific keymaps may want to use this as their parent keymap.")
(put 'default-button 'face 'button)
(put 'default-button 'mouse-face 'highlight)
(put 'default-button 'keymap button-map)
(put 'default-button 'type 'button)
(put 'default-button 'action 'ignore)
(put 'default-button 'help-echo "mouse-2, RET: Push this button")
(put 'default-button 'evaporate t)
(put 'default-button 'rear-nonsticky t)
(put 'button 'button-category-symbol 'default-button)
(defsubst button-category-symbol (type)
"Return the symbol used by button-type TYPE to store properties.
Buttons inherit them by setting their `category' property to that symbol."
(or (get type 'button-category-symbol)
(error "Unknown button type `%s'" type)))
(defun define-button-type (name &rest properties)
"Define a `button type' called NAME.
The remaining arguments form a sequence of PROPERTY VALUE pairs,
specifying properties to use as defaults for buttons with this type
\(a button's type may be set by giving it a `type' property when
creating the button, using the :type keyword argument).
In addition, the keyword argument :supertype may be used to specify a
button-type from which NAME inherits its default property values
\(however, the inheritance happens only when NAME is defined; subsequent
changes to a supertype are not reflected in its subtypes)."
(let ((catsym (make-symbol (concat (symbol-name name) "-button")))
(super-catsym
(button-category-symbol
(or (plist-get properties 'supertype)
(plist-get properties :supertype)
'button))))
(put name 'button-category-symbol catsym)
(let ((default-props (symbol-plist super-catsym)))
(while default-props
(put catsym (pop default-props) (pop default-props))))
(put catsym 'type name)
(while properties
(let ((prop (pop properties)))
(when (eq prop :supertype)
(setq prop 'supertype))
(put catsym prop (pop properties))))
(unless (get catsym 'supertype)
(put catsym 'supertype 'button))
name))
(defun button-type-put (type prop val)
"Set the button-type TYPE's PROP property to VAL."
(put (button-category-symbol type) prop val))
(defun button-type-get (type prop)
"Get the property of button-type TYPE named PROP."
(get (button-category-symbol type) prop))
(defun button-type-subtype-p (type supertype)
"Return t if button-type TYPE is a subtype of SUPERTYPE."
(or (eq type supertype)
(and type
(button-type-subtype-p (button-type-get type 'supertype)
supertype))))
(defun button-start (button)
"Return the position at which BUTTON starts."
(if (overlayp button)
(overlay-start button)
(or (previous-single-property-change (1+ button) 'button)
(point-min))))
(defun button-end (button)
"Return the position at which BUTTON ends."
(if (overlayp button)
(overlay-end button)
(or (next-single-property-change button 'button)
(point-max))))
(defun button-get (button prop)
"Get the property of button BUTTON named PROP."
(if (overlayp button)
(overlay-get button prop)
(get-text-property button prop)))
(defun button-put (button prop val)
"Set BUTTON's PROP property to VAL."
(cond ((memq prop '(type :type))
(setq prop 'category)
(setq val (button-category-symbol val)))
((eq prop 'category)
(error "Button `category' property may not be set directly")))
(if (overlayp button)
(overlay-put button prop val)
(put-text-property
(or (previous-single-property-change (1+ button) 'button)
(point-min))
(or (next-single-property-change button 'button)
(point-max))
prop val)))
(defsubst button-activate (button &optional use-mouse-action)
"Call BUTTON's action property.
If USE-MOUSE-ACTION is non-nil, invoke the button's mouse-action
instead of its normal action; if the button has no mouse-action,
the normal action is used instead."
(let ((action (or (and use-mouse-action (button-get button 'mouse-action))
(button-get button 'action))))
(if (markerp action)
(save-selected-window
(select-window (display-buffer (marker-buffer action)))
(goto-char action)
(recenter 0))
(funcall action button))))
(defun button-label (button)
"Return BUTTON's text label."
(buffer-substring-no-properties (button-start button) (button-end button)))
(defsubst button-type (button)
"Return BUTTON's button-type."
(button-get button 'type))
(defun button-has-type-p (button type)
"Return t if BUTTON has button-type TYPE, or one of TYPE's subtypes."
(button-type-subtype-p (button-get button 'type) type))
(defun make-button (beg end &rest properties)
"Make a button from BEG to END in the current buffer.
The remaining arguments form a sequence of PROPERTY VALUE pairs,
specifying properties to add to the button.
In addition, the keyword argument :type may be used to specify a
button-type from which to inherit other properties; see
`define-button-type'.
Also see `make-text-button', `insert-button'."
(let ((overlay (make-overlay beg end nil t nil)))
(while properties
(button-put overlay (pop properties) (pop properties)))
(overlay-put overlay 'button overlay)
(unless (overlay-get overlay 'category)
(overlay-put overlay 'category 'default-button))
overlay))
(defun insert-button (label &rest properties)
"Insert a button with the label LABEL.
The remaining arguments form a sequence of PROPERTY VALUE pairs,
specifying properties to add to the button.
In addition, the keyword argument :type may be used to specify a
button-type from which to inherit other properties; see
`define-button-type'.
Also see `insert-text-button', `make-button'."
(apply #'make-button
(prog1 (point) (insert label))
(point)
properties))
(defun make-text-button (beg end &rest properties)
"Make a button from BEG to END in the current buffer.
The remaining arguments form a sequence of PROPERTY VALUE pairs,
specifying properties to add to the button.
In addition, the keyword argument :type may be used to specify a
button-type from which to inherit other properties; see
`define-button-type'.
This function is like `make-button', except that the button is actually
part of the text instead of being a property of the buffer. Creating
large numbers of buttons can also be somewhat faster using
`make-text-button'.
Also see `insert-text-button'."
(let ((type-entry
(or (plist-member properties 'type)
(plist-member properties :type))))
(when (plist-get properties 'category)
(error "Button `category' property may not be set directly"))
(if (null type-entry)
(setq properties (cons 'category (cons 'default-button properties)))
(setcar type-entry 'category)
(setcar (cdr type-entry)
(button-category-symbol (car (cdr type-entry))))))
(add-text-properties beg end
(cons 'button (cons (list t) properties)))
beg)
(defun insert-text-button (label &rest properties)
"Insert a button with the label LABEL.
The remaining arguments form a sequence of PROPERTY VALUE pairs,
specifying properties to add to the button.
In addition, the keyword argument :type may be used to specify a
button-type from which to inherit other properties; see
`define-button-type'.
This function is like `insert-button', except that the button is
actually part of the text instead of being a property of the buffer.
Creating large numbers of buttons can also be somewhat faster using
`insert-text-button'.
Also see `make-text-button'."
(apply #'make-text-button
(prog1 (point) (insert label))
(point)
properties))
(defun button-at (pos)
"Return the button at position POS in the current buffer, or nil."
(let ((button (get-char-property pos 'button)))
(if (or (overlayp button) (null button))
button
(copy-marker pos t))))
(defun next-button (pos &optional count-current)
"Return the next button after position POS in the current buffer.
If COUNT-CURRENT is non-nil, count any button at POS in the search,
instead of starting at the next button."
(unless count-current
(setq pos (next-single-char-property-change pos 'button)))
(and (< pos (point-max))
(or (button-at pos)
(next-button pos))))
(defun previous-button (pos &optional count-current)
"Return the previous button before position POS in the current buffer.
If COUNT-CURRENT is non-nil, count any button at POS in the search,
instead of starting at the next button."
(let ((button (button-at pos)))
(if button
(if count-current
button
(setq pos (previous-single-char-property-change
(button-start button) 'button))
(let ((new-button (button-at pos)))
(if new-button
(unless (= pos (button-start button)) new-button)
(previous-button pos))))
(setq pos (previous-single-char-property-change pos 'button))
(or (button-at pos)
(and (> pos (point-min))
(button-at (1- pos)))))))
(defun push-button (&optional pos use-mouse-action)
"Perform the action specified by a button at location POS.
POS may be either a buffer position or a mouse-event. If
USE-MOUSE-ACTION is non-nil, invoke the button's mouse-action
instead of its normal action; if the button has no mouse-action,
the normal action is used instead. The action may be either a
function to call or a marker to display.
POS defaults to point, except when `push-button' is invoked
interactively as the result of a mouse-event, in which case, the
mouse event is used.
If there's no button at POS, do nothing and return nil, otherwise
return t."
(interactive
(list (if (integerp last-command-event) (point) last-command-event)))
(if (and (not (integerp pos)) (eventp pos))
(let ((posn (event-start pos)))
(with-current-buffer (window-buffer (posn-window posn))
(push-button (posn-point posn) t)))
(let ((button (button-at (or pos (point)))))
(if (not button)
nil
(button-activate button use-mouse-action)
t))))
(defun forward-button (n &optional wrap display-message)
"Move to the Nth next button, or Nth previous button if N is negative.
If N is 0, move to the start of any button at point.
If WRAP is non-nil, moving past either end of the buffer continues from the
other end.
If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.
Any button with a non-nil `skip' property is skipped over.
Returns the button found."
(interactive "p\nd\nd")
(let (button)
(if (zerop n)
(if (setq button (button-at (point)))
(goto-char (button-start button)))
(let ((iterator (if (> n 0) #'next-button #'previous-button))
(wrap-start (if (> n 0) (point-min) (point-max))))
(setq n (abs n))
(setq button t) (while (and (> n 0) button)
(setq button (funcall iterator (point)))
(when (and (not button) wrap)
(setq button (funcall iterator wrap-start t)))
(when button
(goto-char (button-start button))
(unless (button-get button 'skip)
(setq n (1- n)))))))
(if (null button)
(error (if wrap "No buttons!" "No more buttons"))
(let ((msg (and display-message (button-get button 'help-echo))))
(when msg
(message "%s" msg)))
button)))
(defun backward-button (n &optional wrap display-message)
"Move to the Nth previous button, or Nth next button if N is negative.
If N is 0, move to the start of any button at point.
If WRAP is non-nil, moving past either end of the buffer continues from the
other end.
If DISPLAY-MESSAGE is non-nil, the button's help-echo string is displayed.
Any button with a non-nil `skip' property is skipped over.
Returns the button found."
(interactive "p\nd\nd")
(forward-button (- n) wrap display-message))
(provide 'button)