(require 'button)
(require 'view)
(defvar help-mode-map (make-sparse-keymap)
"Keymap for help mode.")
(set-keymap-parent help-mode-map button-buffer-map)
(define-key help-mode-map [mouse-2] 'help-follow-mouse)
(define-key help-mode-map "\C-c\C-b" 'help-go-back)
(define-key help-mode-map "\C-c\C-c" 'help-follow-symbol)
(define-key help-mode-map "\r" 'help-follow)
(defvar help-xref-stack nil
"A stack of ways by which to return to help buffers after following xrefs.
Used by `help-follow' and `help-xref-go-back'.
An element looks like (POSITION FUNCTION ARGS...).
To use the element, do (apply FUNCTION ARGS) then goto the point.")
(put 'help-xref-stack 'permanent-local t)
(make-variable-buffer-local 'help-xref-stack)
(defvar help-xref-stack-item nil
"An item for `help-follow' in this buffer to push onto `help-xref-stack'.
The format is (FUNCTION ARGS...).")
(put 'help-xref-stack-item 'permanent-local t)
(make-variable-buffer-local 'help-xref-stack-item)
(setq-default help-xref-stack nil help-xref-stack-item nil)
(defcustom help-mode-hook nil
"Hook run by `help-mode'."
:type 'hook
:group 'help)
(define-button-type 'help-xref
'follow-link t
'action #'help-button-action)
(defun help-button-action (button)
"Call BUTTON's help function."
(help-do-xref (button-start button)
(button-get button 'help-function)
(button-get button 'help-args)))
(define-button-type 'help-function
:supertype 'help-xref
'help-function 'describe-function
'help-echo (purecopy "mouse-2, RET: describe this function"))
(define-button-type 'help-variable
:supertype 'help-xref
'help-function 'describe-variable
'help-echo (purecopy "mouse-2, RET: describe this variable"))
(define-button-type 'help-face
:supertype 'help-xref
'help-function 'describe-face
'help-echo (purecopy "mouse-2, RET: describe this face"))
(define-button-type 'help-coding-system
:supertype 'help-xref
'help-function 'describe-coding-system
'help-echo (purecopy "mouse-2, RET: describe this coding system"))
(define-button-type 'help-input-method
:supertype 'help-xref
'help-function 'describe-input-method
'help-echo (purecopy "mouse-2, RET: describe this input method"))
(define-button-type 'help-character-set
:supertype 'help-xref
'help-function 'describe-character-set
'help-echo (purecopy "mouse-2, RET: describe this character set"))
(define-button-type 'help-symbol
:supertype 'help-xref
'help-function #'help-xref-interned
'help-echo (purecopy "mouse-2, RET: describe this symbol"))
(define-button-type 'help-back
:supertype 'help-xref
'help-function #'help-xref-go-back
'help-echo (purecopy "mouse-2, RET: go back to previous help buffer"))
(define-button-type 'help-info
:supertype 'help-xref
'help-function #'info
'help-echo (purecopy "mouse-2, RET: read this Info node"))
(define-button-type 'help-url
:supertype 'help-xref
'help-function #'browse-url
'help-echo (purecopy "mouse-2, RET: view this URL in a browser"))
(define-button-type 'help-customize-variable
:supertype 'help-xref
'help-function (lambda (v)
(customize-variable v))
'help-echo (purecopy "mouse-2, RET: customize variable"))
(define-button-type 'help-customize-face
:supertype 'help-xref
'help-function (lambda (v)
(customize-face v))
'help-echo (purecopy "mouse-2, RET: customize face"))
(define-button-type 'help-function-def
:supertype 'help-xref
'help-function (lambda (fun file)
(require 'find-func)
(when (eq file 'C-source)
(setq file
(help-C-file-name (indirect-function fun) 'fun)))
(let ((location
(find-function-search-for-symbol fun nil file)))
(pop-to-buffer (car location))
(if (cdr location)
(goto-char (cdr location))
(message "Unable to find location in file"))))
'help-echo (purecopy "mouse-2, RET: find function's definition"))
(define-button-type 'help-variable-def
:supertype 'help-xref
'help-function (lambda (var &optional file)
(when (eq file 'C-source)
(setq file (help-C-file-name var 'var)))
(let ((location (find-variable-noselect var file)))
(pop-to-buffer (car location))
(if (cdr location)
(goto-char (cdr location))
(message "Unable to find location in file"))))
'help-echo (purecopy "mouse-2, RET: find variable's definition"))
(define-button-type 'help-face-def
:supertype 'help-xref
'help-function (lambda (fun file)
(require 'find-func)
(let ((location
(find-function-search-for-symbol fun 'defface file)))
(pop-to-buffer (car location))
(if (cdr location)
(goto-char (cdr location))
(message "Unable to find location in file"))))
'help-echo (purecopy "mouse-2, RET: find face's definition"))
(defun help-mode ()
"Major mode for viewing help text and navigating references in it.
Entry to this mode runs the normal hook `help-mode-hook'.
Commands:
\\{help-mode-map}"
(interactive)
(kill-all-local-variables)
(use-local-map help-mode-map)
(setq mode-name "Help")
(setq major-mode 'help-mode)
(view-mode)
(make-local-variable 'view-no-disable-on-exit)
(setq view-no-disable-on-exit t)
(setq view-exit-action (lambda (buffer)
(or (window-minibuffer-p (selected-window))
(one-window-p t)
(delete-window))))
(run-mode-hooks 'help-mode-hook))
(defun help-mode-setup ()
(help-mode)
(setq buffer-read-only nil))
(defun help-mode-finish ()
(let ((entry (assq (selected-window) view-return-to-alist)))
(if entry
nil
(setq view-return-to-alist
(cons (cons (selected-window) help-return-method)
view-return-to-alist))))
(when (eq major-mode 'help-mode)
(toggle-read-only 1)
(help-make-xrefs (current-buffer))))
(defvar help-back-label (purecopy "[back]")
"Label to use by `help-make-xrefs' for the go-back reference.")
(defconst help-xref-symbol-regexp
(purecopy (concat "\\(\\<\\(\\(variable\\|option\\)\\|" "\\(function\\|command\\)\\|" "\\(face\\)\\|" "\\(symbol\\|program\\|property\\)\\|" "\\(source \\(?:code \\)?\\(?:of\\|for\\)\\)\\)"
"[ \t\n]+\\)?"
"`\\(\\sw\\(\\sw\\|\\s_\\)+\\)'"))
"Regexp matching doc string references to symbols.
The words preceding the quoted symbol can be used in doc strings to
distinguish references to variables, functions and symbols.")
(defvar help-xref-mule-regexp nil
"Regexp matching doc string references to MULE-related keywords.
It is usually nil, and is temporarily bound to an appropriate regexp
when help commands related to multilingual environment (e.g.,
`describe-coding-system') are invoked.")
(defconst help-xref-info-regexp
(purecopy "\\<[Ii]nfo[ \t\n]+\\(node\\|anchor\\)[ \t\n]+`\\([^']+\\)'")
"Regexp matching doc string references to an Info node.")
(defconst help-xref-url-regexp
(purecopy "\\<[Uu][Rr][Ll][ \t\n]+`\\([^']+\\)'")
"Regexp matching doc string references to a URL.")
(defun help-setup-xref (item interactive-p)
"Invoked from commands using the \"*Help*\" buffer to install some xref info.
ITEM is a (FUNCTION . ARGS) pair appropriate for recreating the help
buffer after following a reference. INTERACTIVE-P is non-nil if the
calling command was invoked interactively. In this case the stack of
items for help buffer \"back\" buttons is cleared.
This should be called very early, before the output buffer is cleared,
because we want to record the \"previous\" position of point so we can
restore it properly when going back."
(with-current-buffer (help-buffer)
(when help-xref-stack-item
(push (cons (point) help-xref-stack-item) help-xref-stack))
(when interactive-p
(let ((tail (nthcdr 10 help-xref-stack)))
(if tail (setcdr tail nil))))
(setq help-xref-stack-item item)))
(defvar help-xref-following nil
"Non-nil when following a help cross-reference.")
(defun help-buffer ()
(buffer-name (if help-xref-following
(current-buffer)
(get-buffer-create "*Help*"))))
(defvar help-xref-override-view-map
(let ((map (make-sparse-keymap)))
(set-keymap-parent map view-mode-map)
(define-key map "\r" nil)
map)
"Replacement keymap for `view-mode' in help buffers.")
(defun help-make-xrefs (&optional buffer)
"Parse and hyperlink documentation cross-references in the given BUFFER.
Find cross-reference information in a buffer and activate such cross
references for selection with `help-follow'. Cross-references have
the canonical form `...' and the type of reference may be
disambiguated by the preceding word(s) used in
`help-xref-symbol-regexp'. Faces only get cross-referenced if
preceded or followed by the word `face'. Variables without
variable documentation do not get cross-referenced, unless
preceded by the word `variable' or `option'.
If the variable `help-xref-mule-regexp' is non-nil, find also
cross-reference information related to multilingual environment
\(e.g., coding-systems). This variable is also used to disambiguate
the type of reference as the same way as `help-xref-symbol-regexp'.
A special reference `back' is made to return back through a stack of
help buffers. Variable `help-back-label' specifies the text for
that."
(interactive "b")
(save-excursion
(set-buffer (or buffer (current-buffer)))
(goto-char (point-min))
(forward-paragraph)
(let ((old-modified (buffer-modified-p)))
(let ((stab (syntax-table))
(case-fold-search t)
(inhibit-read-only t))
(set-syntax-table emacs-lisp-mode-syntax-table)
(unwind-protect
(progn
(save-excursion
(while (re-search-forward help-xref-info-regexp nil t)
(let ((data (match-string 2)))
(save-match-data
(unless (string-match "^([^)]+)" data)
(setq data (concat "(emacs)" data))))
(help-xref-button 2 'help-info data))))
(save-excursion
(while (re-search-forward help-xref-url-regexp nil t)
(let ((data (match-string 1)))
(help-xref-button 1 'help-url data))))
(if help-xref-mule-regexp
(save-excursion
(while (re-search-forward help-xref-mule-regexp nil t)
(let* ((data (match-string 7))
(sym (intern-soft data)))
(cond
((match-string 3) (and sym (coding-system-p sym)
(help-xref-button 6 'help-coding-system sym)))
((match-string 4) (and (assoc data input-method-alist)
(help-xref-button 7 'help-input-method data)))
((or (match-string 5) (match-string 6)) (and sym (charsetp sym)
(help-xref-button 7 'help-character-set sym)))
((assoc data input-method-alist)
(help-xref-button 7 'help-character-set data))
((and sym (coding-system-p sym))
(help-xref-button 7 'help-coding-system sym))
((and sym (charsetp sym))
(help-xref-button 7 'help-character-set sym)))))))
(save-excursion
(while (re-search-forward help-xref-symbol-regexp nil t)
(let* ((data (match-string 8))
(sym (intern-soft data)))
(if sym
(cond
((match-string 3) (and (or (boundp sym) (get sym 'variable-documentation))
(help-xref-button 8 'help-variable sym)))
((match-string 4) (and (fboundp sym) (help-xref-button 8 'help-function sym)))
((match-string 5) (and (facep sym)
(help-xref-button 8 'help-face sym)))
((match-string 6)) ((match-string 7)
(help-xref-button 8 'help-function-def sym))
((and
(facep sym)
(save-match-data (looking-at "[ \t\n]+face\\W")))
(help-xref-button 8 'help-face sym))
((and (or (boundp sym)
(get sym 'variable-documentation))
(fboundp sym))
(help-xref-button 8 'help-symbol sym))
((and
(or (boundp sym)
(get sym 'variable-documentation))
(or
(documentation-property
sym 'variable-documentation)
(condition-case nil
(documentation-property
(indirect-variable sym)
'variable-documentation)
(cyclic-variable-indirection nil))))
(help-xref-button 8 'help-variable sym))
((fboundp sym)
(help-xref-button 8 'help-function sym)))))))
(save-excursion
(while (re-search-forward
"\\<M-x\\s-+\\(\\sw\\(\\sw\\|-\\)+\\)" nil t)
(let ((sym (intern-soft (match-string 1))))
(if (fboundp sym)
(help-xref-button 1 'help-function sym)))))
(save-excursion
(goto-char (point-min))
(while (re-search-forward "^key +binding\n\\(-+ +\\)-+\n\n"
nil t)
(let ((col (- (match-end 1) (match-beginning 1))))
(while
(and (not (eobp))
(not (looking-at "\n\\s-*\n")))
(and (eolp) (forward-line))
(end-of-line)
(skip-chars-backward "^\t\n")
(if (and (>= (current-column) col)
(looking-at "\\(\\sw\\|-\\)+$"))
(let ((sym (intern-soft (match-string 0))))
(if (fboundp sym)
(help-xref-button 0 'help-function sym))))
(forward-line))))))
(set-syntax-table stab))
(goto-char (point-max))
(while (and (not (bobp)) (bolp))
(delete-char -1))
(insert "\n")
(when help-xref-stack
(insert "\n")
(help-insert-xref-button help-back-label 'help-back
(current-buffer))
(insert "\n")))
(set (make-local-variable 'minor-mode-overriding-map-alist)
(list (cons 'view-mode help-xref-override-view-map)))
(set-buffer-modified-p old-modified))))
(defun help-xref-button (match-number type &rest args)
"Make a hyperlink for cross-reference text previously matched.
MATCH-NUMBER is the subexpression of interest in the last matched
regexp. TYPE is the type of button to use. Any remaining arguments are
passed to the button's help-function when it is invoked.
See `help-make-xrefs'."
(unless (button-at (match-beginning match-number))
(make-text-button (match-beginning match-number)
(match-end match-number)
'type type 'help-args args)))
(defun help-insert-xref-button (string type &rest args)
"Insert STRING and make a hyperlink from cross-reference text on it.
TYPE is the type of button to use. Any remaining arguments are passed
to the button's help-function when it is invoked.
See `help-make-xrefs'."
(unless (button-at (point))
(insert-text-button string 'type type 'help-args args)))
(defun help-xref-on-pp (from to)
"Add xrefs for symbols in `pp's output between FROM and TO."
(if (> (- to from) 5000) nil
(with-syntax-table emacs-lisp-mode-syntax-table
(save-excursion
(save-restriction
(narrow-to-region from to)
(goto-char (point-min))
(condition-case nil
(while (not (eobp))
(cond
((looking-at "\"") (forward-sexp 1))
((looking-at "#<") (search-forward ">" nil 'move))
((looking-at "\\(\\(\\sw\\|\\s_\\)+\\)")
(let* ((sym (intern-soft (match-string 1)))
(type (cond ((fboundp sym) 'help-function)
((or (memq sym '(t nil))
(keywordp sym))
nil)
((and sym
(or (boundp sym)
(get sym
'variable-documentation)))
'help-variable))))
(when type (help-xref-button 1 type sym)))
(goto-char (match-end 1)))
(t (forward-char 1))))
(error nil)))))))
(defun help-xref-interned (symbol)
"Follow a hyperlink which appeared to be an arbitrary interned SYMBOL.
Both variable, function and face documentation are extracted into a single
help buffer."
(with-current-buffer (help-buffer)
(help-setup-xref nil nil)
(let ((facedoc (when (facep symbol)
(setq help-xref-stack-item nil)
(describe-face symbol)))
(fdoc (when (fboundp symbol)
(setq help-xref-stack-item nil)
(describe-function symbol)))
(sdoc (when (or (boundp symbol)
(get symbol 'variable-documentation))
(setq help-xref-stack-item nil)
(describe-variable symbol))))
(cond
(sdoc
(when (or fdoc facedoc)
(goto-char (point-min))
(let ((inhibit-read-only t))
(when fdoc
(insert fdoc "\n\n")
(when facedoc
(insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
" is also a " "face." "\n\n")))
(when facedoc
(insert facedoc "\n\n"))
(insert (make-string 30 ?-) "\n\n" (symbol-name symbol)
" is also a " "variable." "\n\n"))
(setq help-xref-stack-item nil)
(help-setup-xref (list #'help-xref-interned symbol) nil)))
(fdoc
(when facedoc
(goto-char (point-max))
(let ((inhibit-read-only t))
(insert "\n\n" (make-string 30 ?-) "\n\n" (symbol-name symbol)
" is also a " "face." "\n\n" facedoc))
(setq help-xref-stack-item nil)
(help-setup-xref (list #'help-xref-interned symbol) nil)))))))
(defun help-xref-go-back (buffer)
"From BUFFER, go back to previous help buffer text using `help-xref-stack'."
(let (item position method args)
(with-current-buffer buffer
(when help-xref-stack
(setq item (pop help-xref-stack)
help-xref-stack-item nil
position (car item)
method (cadr item)
args (cddr item))))
(apply method args)
(with-current-buffer buffer
(if (get-buffer-window buffer)
(set-window-point (get-buffer-window buffer) position)
(goto-char position)))))
(defun help-go-back ()
"Go back to previous topic in this help buffer."
(interactive)
(if help-xref-stack
(help-xref-go-back (current-buffer))
(error "No previous help buffer")))
(defun help-do-xref (pos function args)
"Call the help cross-reference function FUNCTION with args ARGS.
Things are set up properly so that the resulting help-buffer has
a proper [back] button."
(let ((help-xref-following t))
(apply function args)))
(defun help-follow-mouse ()
"Follow the cross-reference that you click on."
(interactive)
(error "No cross-reference here"))
(defun help-follow ()
"Follow cross-reference at point.
For the cross-reference format, see `help-make-xrefs'."
(interactive)
(error "No cross-reference here"))
(defun help-follow-symbol (&optional pos)
"In help buffer, show docs for symbol at POS, defaulting to point.
Show all docs for that symbol as either a variable, function or face."
(interactive "d")
(unless pos
(setq pos (point)))
(let ((sym
(intern
(save-excursion
(goto-char pos) (skip-syntax-backward "w_")
(buffer-substring (point)
(progn (skip-syntax-forward "w_")
(point)))))))
(when (or (boundp sym)
(get sym 'variable-documentation)
(fboundp sym) (facep sym))
(help-do-xref pos #'help-xref-interned (list sym)))))
(defun help-insert-string (string)
"Insert STRING to the help buffer and install xref info for it.
This function can be used to restore the old contents of the help buffer
when going back to the previous topic in the xref stack. It is needed
in case when it is impossible to recompute the old contents of the
help buffer by other means."
(setq help-xref-stack-item (list #'help-insert-string string))
(with-output-to-temp-buffer (help-buffer)
(insert string)))
(provide 'help-mode)