tcsh.defaults   [plain text]


##
# TCSH Expanded C-Shell INITIALIZATION FILE
# User preferences file
# Override these in rc.mine
#
# Wilfredo Sanchez Jr. | tritan@mit.edu
# July 09, 1992
#
# MIT Project Athena
##

if ($?prompt) then		# For interactive shells only (ie. not scripts):

  # Set up prompt
  set promptchars = "%#"
  if ("$version" =~ tcsh*) then
    set prompt = "[%m:%c3] %n%# "
  else
    if ($uid) then
      set prompt = "[$host] $user% "
    else
      set prompt = "[$host] $user# "
    endif
  endif
  set prompt2 = "%R -> "	# if/while prompt
  set prompt3 = "OK? %R? "	# Spell correction prompt

  # History
  set history = 150			# Number of commands saved as history
  set savehist = 150
  #set histlit				# Save literal (unparsed) history
  set histfile = ~/.tcsh_history	# History file

  set cdpath = (~)			# Path to search for directory changes

  # Word Completion
  set fignore = ( \~ .bak .o .bin RCS CVS )
  set nostat = (/afs /net /Net /Network/Servers)
  set recexact			# Exact word expands as well as beeps
  set autolist			# List matching words
  set matchbeep = notunique	# Beep if not unique
  set autoexpand		# Expand history when completing
  set autocorrect		# Correct spelling when completing
  #set nobeep			# Don't beep when complete

  # pushd/popd/cd
  set dextract			# pushd +n gets stack item n
  set dunique			# Only push unique directories
  #set pushdtohome		# 'pushd' = 'pushd ~'
  set symlinks = ignore		# 'cd ..' goes to previous dir, not $cwd/..

  # Random
  set correct = cmd		# Spell Correction on
  set inputmode = insert	# Insert chars (not overwrite)
  set listjobs = long		# List all jobs when suspending (long format)
  set nokanji			# Disable kanji if enabled
  #set rmstar			# Prompt before doing 'rm *'

  # Command to execute before each prompt
  #alias precmd 'noop'

  # Command to execute periodically
  #set tperiod = 10			# Period, in minutes
  #alias periodic touch /dev/$tty	# Command

  # Command to execute after changing directory
  #alias cwdcmd 'noop'

  # Command to execute when tcsh wants to beep.
  #alias beepcmp 'noop'

  # Automatic Logout/Lock
  #set autologout = "60 10"	# Logout after 60 minutes, lock after 10

  # Time reporting
  #set time = 10

  # WATCH FOR LOCAL LOGGINS
  #set watch = ( 1 any any )
  #set who = "%B%n%b %a %l from host %B%M%b at %t"

  # Use builtin version of ls (= ls -CF) because it's faster
  #alias ls 'ls-F'

endif