with Ada.Text_IO;
with Ada.Strings.Unbounded;
with Ada.Exceptions;
with Ada.Command_Line;
with GNAT.OS_Lib;
with GNAT.Command_Line;
with Gnatvsn;
with MDLL.Fil;
with MDLL.Utl;
procedure Gnatdll is
use GNAT;
use Ada;
use MDLL;
use Ada.Strings.Unbounded;
use type OS_Lib.Argument_List;
procedure Syntax;
procedure Check (Filename : String);
procedure Parse_Command_Line;
procedure Check_Context;
Syntax_Error : exception;
Context_Error : exception;
Help : Boolean := False;
Version : constant String := Gnatvsn.Gnat_Version_String;
Default_DLL_Address : constant String := "0x11000000";
Lib_Filename : Unbounded_String := Null_Unbounded_String;
Def_Filename : Unbounded_String := Null_Unbounded_String;
List_Filename : Unbounded_String := Null_Unbounded_String;
DLL_Address : Unbounded_String :=
To_Unbounded_String (Default_DLL_Address);
Objects_Files : Argument_List_Access := Null_Argument_List_Access;
Ali_Files : Argument_List_Access := Null_Argument_List_Access;
Options : Argument_List_Access := Null_Argument_List_Access;
Largs_Options : Argument_List_Access := Null_Argument_List_Access;
Bargs_Options : Argument_List_Access := Null_Argument_List_Access;
type Build_Mode_State is (Import_Lib, Dynamic_Lib, Dynamic_Lib_Only, Nil);
Build_Mode : Build_Mode_State := Nil;
Must_Build_Relocatable : Boolean := True;
procedure Syntax is
use Text_IO;
procedure P (Str : in String) renames Text_IO.Put_Line;
begin
P ("Usage : gnatdll [options] [list-of-files]");
New_Line;
P ("[list-of-files] a list of Ada libraries (.ali) and/or " &
"foreign object files");
New_Line;
P ("[options] can be");
P (" -h Help - display this message");
P (" -v Verbose");
P (" -q Quiet");
P (" -k Remove @nn suffix from exported names");
P (" -g Generate debugging information");
P (" -Idir Specify source and object files search path");
P (" -l file File contains a list-of-files to be added to "
& "the library");
P (" -e file Definition file containing exports");
P (" -d file Put objects in the relocatable dynamic "
& "library <file>");
P (" -b addr Set base address for the relocatable DLL");
P (" default address is " & Default_DLL_Address);
P (" -a[addr] Build non-relocatable DLL at address <addr>");
P (" if <addr> is not specified use "
& Default_DLL_Address);
P (" -n No-import - do not create the import library");
P (" -bargs opts opts are passed to the binder");
P (" -largs opts opts are passed to the linker");
end Syntax;
procedure Check (Filename : in String) is
begin
if not OS_Lib.Is_Regular_File (Filename) then
Exceptions.Raise_Exception (Context_Error'Identity,
"Error: " & Filename & " not found.");
end if;
end Check;
procedure Parse_Command_Line is
use GNAT.Command_Line;
procedure Add_File (Filename : in String);
procedure Add_Files_From_List (List_Filename : in String);
Max_Files : constant := 5_000;
Max_Options : constant := 100;
Ofiles : OS_Lib.Argument_List (1 .. Max_Files);
O : Positive := Ofiles'First;
Afiles : OS_Lib.Argument_List (1 .. Max_Files);
A : Positive := Afiles'First;
Gopts : OS_Lib.Argument_List (1 .. Max_Options);
G : Positive := Gopts'First;
Lopts : OS_Lib.Argument_List (1 .. Max_Options);
L : Positive := Lopts'First;
Bopts : OS_Lib.Argument_List (1 .. Max_Options);
B : Positive := Bopts'First;
Build_Import : Boolean := True;
procedure Add_File (Filename : in String) is
begin
if Fil.Is_Ali (Filename) then
Check (Filename);
Afiles (A) := new String'(Filename);
A := A + 1;
elsif Fil.Is_Obj (Filename) then
Check (Filename);
Ofiles (O) := new String'(Filename);
O := O + 1;
else
Exceptions.Raise_Exception
(Syntax_Error'Identity,
"don't know what to do with " & Filename & " !");
end if;
end Add_File;
procedure Add_Files_From_List (List_Filename : in String) is
File : Text_IO.File_Type;
Buffer : String (1 .. 500);
Last : Natural;
begin
Text_IO.Open (File, Text_IO.In_File, List_Filename);
while not Text_IO.End_Of_File (File) loop
Text_IO.Get_Line (File, Buffer, Last);
Add_File (Buffer (1 .. Last));
end loop;
Text_IO.Close (File);
end Add_Files_From_List;
begin
Initialize_Option_Scan ('-', False, "bargs largs");
loop
case Getopt ("g h v q k a? b: d: e: l: n I:") is
when ASCII.Nul =>
exit;
when 'h' =>
Help := True;
when 'g' =>
Gopts (G) := new String'("-g");
G := G + 1;
when 'v' =>
MDLL.Verbose := True;
if MDLL.Quiet then
Exceptions.Raise_Exception
(Syntax_Error'Identity,
"impossible to use -q and -v together.");
end if;
when 'q' =>
MDLL.Quiet := True;
if MDLL.Verbose then
Exceptions.Raise_Exception
(Syntax_Error'Identity,
"impossible to use -v and -q together.");
end if;
when 'k' =>
MDLL.Kill_Suffix := True;
when 'a' =>
if Parameter = "" then
DLL_Address := To_Unbounded_String (Default_DLL_Address);
else
DLL_Address := To_Unbounded_String (Parameter);
end if;
Must_Build_Relocatable := False;
when 'b' =>
DLL_Address := To_Unbounded_String (Parameter);
Must_Build_Relocatable := True;
when 'e' =>
Def_Filename := To_Unbounded_String (Parameter);
when 'd' =>
Lib_Filename := To_Unbounded_String (Parameter);
if Def_Filename = Null_Unbounded_String then
Def_Filename := To_Unbounded_String
(Fil.Ext_To (Parameter, "def"));
end if;
Build_Mode := Dynamic_Lib;
when 'n' =>
Build_Import := False;
when 'l' =>
List_Filename := To_Unbounded_String (Parameter);
when 'I' =>
Gopts (G) := new String'("-I" & Parameter);
G := G + 1;
when others =>
raise Invalid_Switch;
end case;
end loop;
loop
declare
File : constant String := Get_Argument (Do_Expansion => True);
begin
exit when File'Length = 0;
Add_File (File);
end;
end loop;
Goto_Section ("largs");
loop
case Getopt ("*") is
when ASCII.Nul =>
exit;
when others =>
Lopts (L) := new String'(Full_Switch);
L := L + 1;
end case;
end loop;
Goto_Section ("bargs");
loop
case Getopt ("*") is
when ASCII.Nul =>
exit;
when others =>
Bopts (B) := new String'(Full_Switch);
B := B + 1;
end case;
end loop;
if List_Filename /= Null_Unbounded_String then
Add_Files_From_List (To_String (List_Filename));
end if;
if Build_Mode = Nil and then not Help and then not Verbose then
Exceptions.Raise_Exception
(Syntax_Error'Identity,
"nothing to do.");
end if;
if not Build_Import
and then A = Afiles'First
and then O = Ofiles'First
then
Exceptions.Raise_Exception
(Syntax_Error'Identity,
"-n specified but there are no objects to build the library.");
end if;
if Build_Mode = Dynamic_Lib
and then A = Afiles'First
and then O = Ofiles'First
then
Build_Mode := Import_Lib;
end if;
if Build_Mode = Dynamic_Lib and then not Build_Import then
Build_Mode := Dynamic_Lib_Only;
end if;
if O /= Ofiles'First then
Objects_Files := new OS_Lib.Argument_List'(Ofiles (1 .. O - 1));
end if;
if A /= Afiles'First then
Ali_Files := new OS_Lib.Argument_List'(Afiles (1 .. A - 1));
end if;
if G /= Gopts'First then
Options := new OS_Lib.Argument_List'(Gopts (1 .. G - 1));
end if;
if L /= Lopts'First then
Largs_Options := new OS_Lib.Argument_List'(Lopts (1 .. L - 1));
end if;
if B /= Bopts'First then
Bargs_Options := new OS_Lib.Argument_List'(Bopts (1 .. B - 1));
end if;
exception
when Invalid_Switch =>
Exceptions.Raise_Exception
(Syntax_Error'Identity,
Message => "Invalid Switch " & Full_Switch);
when Invalid_Parameter =>
Exceptions.Raise_Exception
(Syntax_Error'Identity,
Message => "No parameter for " & Full_Switch);
end Parse_Command_Line;
procedure Check_Context is
begin
Check (To_String (Def_Filename));
for F in Objects_Files'Range loop
Check (Objects_Files (F).all);
end loop;
end Check_Context;
begin
if Ada.Command_Line.Argument_Count = 0 then
Help := True;
else
Parse_Command_Line;
end if;
if MDLL.Verbose or else Help then
Text_IO.New_Line;
Text_IO.Put_Line ("GNATDLL " & Version & " - Dynamic Libraries Builder");
Text_IO.New_Line;
end if;
MDLL.Utl.Locate;
if Help
or else (MDLL.Verbose and then Ada.Command_Line.Argument_Count = 1)
then
Syntax;
else
Check_Context;
case Build_Mode is
when Import_Lib =>
MDLL.Build_Import_Library
(To_String (Lib_Filename),
To_String (Def_Filename));
when Dynamic_Lib =>
MDLL.Build_Dynamic_Library
(Objects_Files.all,
Ali_Files.all,
Options.all,
Bargs_Options.all,
Largs_Options.all,
To_String (Lib_Filename),
To_String (Def_Filename),
To_String (DLL_Address),
Build_Import => True,
Relocatable => Must_Build_Relocatable);
when Dynamic_Lib_Only =>
MDLL.Build_Dynamic_Library
(Objects_Files.all,
Ali_Files.all,
Options.all,
Bargs_Options.all,
Largs_Options.all,
To_String (Lib_Filename),
To_String (Def_Filename),
To_String (DLL_Address),
Build_Import => False,
Relocatable => Must_Build_Relocatable);
when Nil =>
null;
end case;
end if;
Ada.Command_Line.Set_Exit_Status (Ada.Command_Line.Success);
exception
when SE : Syntax_Error =>
Text_IO.Put_Line ("Syntax error : " & Exceptions.Exception_Message (SE));
Text_IO.New_Line;
Syntax;
Ada.Command_Line.Set_Exit_Status (Ada.Command_Line.Failure);
when E : Tools_Error | Context_Error =>
Text_IO.Put_Line (Exceptions.Exception_Message (E));
Ada.Command_Line.Set_Exit_Status (Ada.Command_Line.Failure);
when others =>
Text_IO.Put_Line ("gnatdll: INTERNAL ERROR. Please report");
Ada.Command_Line.Set_Exit_Status (Ada.Command_Line.Failure);
end Gnatdll;