(eval-when-compile (require 'cl))
(defgroup uniquify nil
"Unique buffer names dependent on file name."
:group 'applications)
(defcustom uniquify-buffer-name-style nil
"*If non-nil, buffer names are uniquified with parts of directory name.
The value determines the buffer name style and is one of `forward',
`reverse', `post-forward', or `post-forward-angle-brackets'.
For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name'
would have the following buffer names in the various styles:
forward bar/mumble/name quux/mumble/name
reverse name\\mumble\\bar name\\mumble\\quux
post-forward name|bar/mumble name|quux/mumble
post-forward-angle-brackets name<bar/mumble> name<quux/mumble>
nil name name<2>"
:type '(radio (const forward)
(const reverse)
(const post-forward)
(const post-forward-angle-brackets)
(const :tag "standard Emacs behavior (nil)" nil))
:require 'uniquify
:group 'uniquify)
(defcustom uniquify-after-kill-buffer-p t
"If non-nil, rerationalize buffer names after a buffer has been killed."
:type 'boolean
:group 'uniquify)
(defcustom uniquify-ask-about-buffer-names-p nil
"*If non-nil, permit user to choose names for buffers with same base file.
If the user chooses to name a buffer, uniquification is preempted and no
other buffer names are changed."
:type 'boolean
:group 'uniquify)
(defcustom uniquify-ignore-buffers-re nil
"*Regular expression matching buffer names that should not be uniquified.
For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename
draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the
visited file name isn't the same as that of the buffer."
:type '(choice (const :tag "Uniquify all buffers" nil) regexp)
:group 'uniquify)
(defcustom uniquify-min-dir-content 0
"*Minimum number of directory name components included in buffer name."
:type 'integer
:group 'uniquify)
(defcustom uniquify-separator nil
"*String separator for buffer name components.
When `uniquify-buffer-name-style' is `post-forward', separates
base file name from directory part in buffer names (default \"|\").
When `uniquify-buffer-name-style' is `reverse', separates all
file name components (default \"\\\")."
:type '(choice (const nil) string)
:group 'uniquify)
(defcustom uniquify-trailing-separator-p nil
"*If non-nil, add a file name separator to dired buffer names.
If `uniquify-buffer-name-style' is `forward', add the separator at the end;
if it is `reverse', add the separator at the beginning; otherwise, this
variable is ignored."
:type 'boolean
:group 'uniquify)
(defcustom uniquify-strip-common-suffix
(eq 0 uniquify-min-dir-content)
"If non-nil, strip common directory suffixes of conflicting files.
E.g. if you open /a1/b/c/d and /a2/b/c/d, the buffer names will say
\"d|a1\" and \"d|a2\" instead of \"d|a1/b/c\" and \"d|a2/b/c\".
This can be handy when you have deep parallel hierarchies."
:type 'boolean
:group 'uniquify)
(defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode)
"List of modes for which uniquify should obey `list-buffers-directory'.
That means that when `buffer-file-name' is set to nil, `list-buffers-directory'
contains the name of the directory which the buffer is visiting.")
(defstruct (uniquify-item
(:constructor nil) (:copier nil)
(:constructor uniquify-make-item
(base dirname buffer &optional proposed)))
base dirname buffer proposed)
(defvar uniquify-possibly-resolvable nil)
(defvar uniquify-managed nil
"Non-nil if the name of this buffer is managed by uniquify.
It actually holds the list of `uniquify-item's corresponding to the conflict.")
(make-variable-buffer-local 'uniquify-managed)
(put 'uniquify-managed 'permanent-local t)
(defun uniquify-rationalize-file-buffer-names (base dirname newbuf)
"Make file buffer names unique by adding segments from file name.
If `uniquify-min-dir-content' > 0, always pulls that many
file name elements.
Arguments BASE, DIRNAME, and NEWBUF specify the new buffer that causes
this rationalization."
(interactive
(list (if uniquify-managed
(uniquify-item-base (car uniquify-managed)) (buffer-name))
(uniquify-buffer-file-name (current-buffer))
(current-buffer)))
(with-current-buffer newbuf (setq uniquify-managed nil))
(when dirname
(setq dirname (expand-file-name (directory-file-name dirname)))
(let ((fix-list (list (uniquify-make-item base dirname newbuf)))
items)
(dolist (buffer (buffer-list))
(when (and (not (and uniquify-ignore-buffers-re
(string-match uniquify-ignore-buffers-re
(buffer-name buffer))))
(setq items (buffer-local-value 'uniquify-managed buffer))
(equal base (uniquify-item-base (car items)))
(not (memq (car items) fix-list)))
(unless (cdr items)
(setf (uniquify-item-dirname (car items))
(uniquify-buffer-file-name
(uniquify-item-buffer (car items))))
(unless (uniquify-item-dirname (car items))
(with-current-buffer (uniquify-item-buffer (car items))
(setq uniquify-managed nil))
(setq items nil)))
(setq fix-list (append fix-list items))))
(uniquify-rationalize fix-list))))
(defun uniquify-buffer-file-name (buffer)
"Return name of directory, file BUFFER is visiting, or nil if none.
Works on ordinary file-visiting buffers and buffers whose mode is mentioned
in `uniquify-list-buffers-directory-modes', otherwise returns nil."
(with-current-buffer buffer
(let ((filename
(or buffer-file-name
(if (memq major-mode uniquify-list-buffers-directory-modes)
list-buffers-directory))))
(when filename
(directory-file-name
(file-name-directory
(expand-file-name
(directory-file-name filename))))))))
(defun uniquify-rerationalize-w/o-cb (fix-list)
"Re-rationalize the buffers in FIX-LIST, but ignoring current-buffer."
(let ((new-fix-list nil))
(dolist (item fix-list)
(let ((buf (uniquify-item-buffer item)))
(unless (or (eq buf (current-buffer)) (not (buffer-live-p buf)))
(push item new-fix-list))))
(when new-fix-list
(uniquify-rationalize new-fix-list))))
(defun uniquify-rationalize (fix-list)
(dolist (item fix-list)
(with-current-buffer (uniquify-item-buffer item)
(setf (uniquify-item-proposed item)
(uniquify-get-proposed-name (uniquify-item-base item)
(uniquify-item-dirname item)))
(setq uniquify-managed fix-list)))
(when (and (cdr fix-list) uniquify-strip-common-suffix)
(let ((strip t))
(while (let* ((base (file-name-nondirectory
(uniquify-item-dirname (car fix-list))))
(items fix-list))
(when (> (length base) 0)
(while (and strip items)
(unless (equal base (file-name-nondirectory
(uniquify-item-dirname (pop items))))
(setq strip nil)))
strip))
(dolist (item (prog1 fix-list (setq fix-list nil)))
(push (uniquify-make-item (uniquify-item-base item)
(let ((f (file-name-directory
(uniquify-item-dirname item))))
(and f (directory-file-name f)))
(uniquify-item-buffer item)
(uniquify-item-proposed item))
fix-list)))))
(uniquify-rationalize-a-list fix-list))
(defun uniquify-item-greaterp (item1 item2)
(string-lessp (uniquify-item-proposed item2)
(uniquify-item-proposed item1)))
(defun uniquify-rationalize-a-list (fix-list &optional depth)
(unless depth (setq depth uniquify-min-dir-content))
(let (conflicting-sublist (old-proposed "")
proposed)
(dolist (item (sort fix-list 'uniquify-item-greaterp))
(setq proposed (uniquify-item-proposed item))
(unless (equal proposed old-proposed)
(uniquify-rationalize-conflicting-sublist conflicting-sublist
old-proposed depth)
(setq conflicting-sublist nil))
(push item conflicting-sublist)
(setq old-proposed proposed))
(uniquify-rationalize-conflicting-sublist conflicting-sublist
old-proposed depth)))
(defun uniquify-get-proposed-name (base dirname &optional depth)
(unless depth (setq depth uniquify-min-dir-content))
(assert (equal (directory-file-name dirname) dirname))
(if (and uniquify-trailing-separator-p
(file-directory-p (expand-file-name base dirname))
(not (string-equal base "")))
(cond ((eq uniquify-buffer-name-style 'forward)
(setq base (file-name-as-directory base)))
((eq uniquify-buffer-name-style 'reverse)
(setq base (concat (or uniquify-separator "\\") base)))))
(let ((extra-string nil)
(n depth))
(while (and (> n 0) dirname)
(let ((file (file-name-nondirectory dirname)))
(when (setq dirname (file-name-directory dirname))
(setq dirname (directory-file-name dirname)))
(setq n (1- n))
(push (if (zerop (length file)) (prog1 "" (setq dirname nil)) file)
extra-string)))
(when (zerop n)
(if (and dirname extra-string
(equal dirname (file-name-directory dirname)))
(push "" extra-string))
(setq uniquify-possibly-resolvable t))
(cond
((null extra-string) base)
((string-equal base "") (mapconcat 'identity extra-string "/"))
((eq uniquify-buffer-name-style 'reverse)
(mapconcat 'identity
(cons base (nreverse extra-string))
(or uniquify-separator "\\")))
((eq uniquify-buffer-name-style 'forward)
(mapconcat 'identity (nconc extra-string (list base))
"/"))
((eq uniquify-buffer-name-style 'post-forward)
(concat base (or uniquify-separator "|")
(mapconcat 'identity extra-string "/")))
((eq uniquify-buffer-name-style 'post-forward-angle-brackets)
(concat base "<" (mapconcat 'identity extra-string "/")
">"))
(t (error "Bad value for uniquify-buffer-name-style: %s"
uniquify-buffer-name-style)))))
(defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth)
(when conf-list
(if (or (cdr conf-list)
(let ((buf (get-buffer old-name)))
(and buf (not (eq buf (uniquify-item-buffer (car conf-list)))))))
(when uniquify-possibly-resolvable
(setq uniquify-possibly-resolvable nil
depth (1+ depth))
(dolist (item conf-list)
(setf (uniquify-item-proposed item)
(uniquify-get-proposed-name
(uniquify-item-base item)
(uniquify-item-dirname item)
depth)))
(uniquify-rationalize-a-list conf-list depth))
(unless (string= old-name "")
(uniquify-rename-buffer (car conf-list) old-name)))))
(defun uniquify-rename-buffer (item newname)
(let ((buffer (uniquify-item-buffer item)))
(unless (equal newname (buffer-name buffer))
(with-current-buffer buffer
(let ((uniquify-buffer-name-style nil)) (rename-buffer newname t))))))
(defadvice rename-buffer (after rename-buffer-uniquify activate)
"Uniquify buffer names with parts of directory name."
(uniquify-maybe-rerationalize-w/o-cb)
(if (null (ad-get-arg 1)) (setq uniquify-managed nil)
(when uniquify-buffer-name-style
(uniquify-rationalize-file-buffer-names
(ad-get-arg 0)
(uniquify-buffer-file-name (current-buffer))
(current-buffer))
(setq ad-return-value (buffer-name (current-buffer))))))
(defadvice create-file-buffer (after create-file-buffer-uniquify activate)
"Uniquify buffer names with parts of directory name."
(if uniquify-buffer-name-style
(let ((filename (expand-file-name (directory-file-name (ad-get-arg 0)))))
(uniquify-rationalize-file-buffer-names
(file-name-nondirectory filename)
(file-name-directory filename) ad-return-value))))
(defun uniquify-maybe-rerationalize-w/o-cb ()
"Re-rationalize buffer names, ignoring current buffer.
For use on `kill-buffer-hook'."
(if (and (cdr uniquify-managed)
uniquify-buffer-name-style
uniquify-after-kill-buffer-p)
(uniquify-rerationalize-w/o-cb uniquify-managed)))
(add-hook 'kill-buffer-hook 'uniquify-maybe-rerationalize-w/o-cb)
(provide 'uniquify)