(eval-when-compile (require 'cl))
(require 'wid-edit)
(defgroup tree-widget nil
"Customization support for the Tree Widget library."
:version "22.1"
:group 'widgets)
(defcustom tree-widget-image-enable
(not (or (featurep 'xemacs) (< emacs-major-version 21)))
"*Non-nil means that tree-widget will try to use images."
:type 'boolean
:group 'tree-widget)
(defvar tree-widget-themes-load-path
'(load-path
(let ((dir (if (fboundp 'locate-data-directory)
(locate-data-directory "tree-widget") data-directory)))
(and dir (list dir (expand-file-name "images" dir))))
)
"List of locations in which to search for the themes sub-directory.
Each element is an expression that will be recursively evaluated until
it returns a single directory or a list of directories.
The default is to search in the `load-path' first, then in the
\"images\" sub directory in the data directory, then in the data
directory.
The data directory is the value of the variable `data-directory' on
Emacs, and what `(locate-data-directory \"tree-widget\")' returns on
XEmacs.")
(defcustom tree-widget-themes-directory "tree-widget"
"*Name of the directory in which to look for an image theme.
When nil use the directory where the tree-widget library is located.
When it is a relative name, search in all occurrences of that sub
directory in the path specified by `tree-widget-themes-load-path'.
The default is to use the \"tree-widget\" relative name."
:type '(choice (const :tag "Default" "tree-widget")
(const :tag "Where is this library" nil)
(directory :format "%{%t%}:\n%v"))
:group 'tree-widget)
(defcustom tree-widget-theme nil
"*Name of the theme in which to look for images.
This is a sub directory of the themes directory specified by the
`tree-widget-themes-directory' option.
The default theme is \"default\". When an image is not found in a
theme, it is searched in its parent theme.
A complete theme must at least contain images with these file names
with a supported extension (see also `tree-widget-image-formats'):
\"guide\"
A vertical guide line.
\"no-guide\"
An invisible vertical guide line.
\"end-guide\"
End of a vertical guide line.
\"handle\"
Horizontal guide line that joins the vertical guide line to an icon.
\"no-handle\"
An invisible handle.
Plus images whose name is given by the :glyph-name property of the
icon widgets used to draw the tree. By default these images are used:
\"open\"
Icon associated to an expanded tree.
\"close\"
Icon associated to a collapsed tree.
\"empty\"
Icon associated to an expanded tree with no child.
\"leaf\"
Icon associated to a leaf node."
:type '(choice (const :tag "Default" nil)
(string :tag "Name"))
:group 'tree-widget)
(defcustom tree-widget-image-properties-emacs
'(:ascent center :mask (heuristic t))
"*Default properties of Emacs images."
:type 'plist
:group 'tree-widget)
(defcustom tree-widget-image-properties-xemacs
nil
"*Default properties of XEmacs images."
:type 'plist
:group 'tree-widget)
(defcustom tree-widget-space-width 0.5
"Amount of space between an icon image and a node widget.
Must be a valid space :width display property."
:group 'tree-widget
:type 'sexp)
(eval-and-compile (cond
((featurep 'xemacs)
(defsubst tree-widget-use-image-p ()
"Return non-nil if image support is currently enabled."
(and tree-widget-image-enable
widget-glyph-enable
(console-on-window-system-p)))
(defsubst tree-widget-create-image (type file &optional props)
"Create an image of type TYPE from FILE, and return it.
Give the image the specified properties PROPS."
(apply 'make-glyph `([,type :file ,file ,@props])))
(defsubst tree-widget-image-formats ()
"Return the alist of image formats/file name extensions.
See also the option `widget-image-file-name-suffixes'."
(delq nil
(mapcar
#'(lambda (fmt)
(and (valid-image-instantiator-format-p (car fmt)) fmt))
widget-image-file-name-suffixes)))
)
(t
(defsubst tree-widget-use-image-p ()
"Return non-nil if image support is currently enabled."
(and tree-widget-image-enable
widget-image-enable
(display-images-p)))
(defsubst tree-widget-create-image (type file &optional props)
"Create an image of type TYPE from FILE, and return it.
Give the image the specified properties PROPS."
(apply 'create-image `(,file ,type nil ,@props)))
(defsubst tree-widget-image-formats ()
"Return the alist of image formats/file name extensions.
See also the option `widget-image-conversion'."
(delq nil
(mapcar
#'(lambda (fmt)
(and (image-type-available-p (car fmt)) fmt))
widget-image-conversion)))
))
)
(defvar tree-widget--theme nil)
(defsubst tree-widget-theme-name ()
"Return the current theme name, or nil if no theme is active."
(and tree-widget--theme (car (aref tree-widget--theme 0))))
(defsubst tree-widget-set-parent-theme (name)
"Set to NAME the parent theme of the current theme.
The default parent theme is the \"default\" theme."
(unless (member name (aref tree-widget--theme 0))
(aset tree-widget--theme 0
(append (aref tree-widget--theme 0) (list name)))
(catch 'found
(dolist (dir (tree-widget-themes-path))
(setq dir (expand-file-name name dir))
(when (file-accessible-directory-p dir)
(throw 'found
(load (expand-file-name
"tree-widget-theme-setup" dir) t)))))))
(defun tree-widget-set-theme (&optional name)
"In the current buffer, set the theme to use for images.
The current buffer must be where the tree widget is drawn.
Optional argument NAME is the name of the theme to use. It defaults
to the value of the variable `tree-widget-theme'.
Does nothing if NAME is already the current theme.
If there is a \"tree-widget-theme-setup\" library in the theme
directory, load it to setup a parent theme or the images properties.
Typically it should contain something like this:
(tree-widget-set-parent-theme \"my-parent-theme\")
(tree-widget-set-image-properties
(if (featurep 'xemacs)
'(:ascent center)
'(:ascent center :mask (heuristic t))
))"
(or name (setq name (or tree-widget-theme "default")))
(unless (string-equal name (tree-widget-theme-name))
(set (make-local-variable 'tree-widget--theme)
(make-vector 4 nil))
(tree-widget-set-parent-theme name)
(tree-widget-set-parent-theme "default")))
(defun tree-widget--locate-sub-directory (name path &optional found)
"Locate all occurrences of the sub-directory NAME in PATH.
Return a list of absolute directory names in reverse order, or nil if
not found."
(condition-case err
(dolist (elt path)
(setq elt (eval elt))
(cond
((stringp elt)
(and (file-accessible-directory-p
(setq elt (expand-file-name name elt)))
(push elt found)))
(elt
(setq found (tree-widget--locate-sub-directory
name (if (atom elt) (list elt) elt) found)))))
(error
(message "In tree-widget--locate-sub-directory: %s"
(error-message-string err))))
found)
(defun tree-widget-themes-path ()
"Return the path where to search for a theme.
It is specified in variable `tree-widget-themes-directory'.
Return a list of absolute directory names, or nil when no directory
has been found accessible."
(let ((path (aref tree-widget--theme 1)))
(cond
((eq path 'void) nil)
(path)
((null tree-widget-themes-directory)
(when (setq path (locate-library "tree-widget"))
(setq path (file-name-directory path))
(setq path (and (file-accessible-directory-p path)
(list path)))
(aset tree-widget--theme 1 (or path 'void))
path))
((file-name-absolute-p tree-widget-themes-directory)
(setq path (expand-file-name tree-widget-themes-directory))
(setq path (and (file-accessible-directory-p path)
(list path)))
(aset tree-widget--theme 1 (or path 'void))
path)
(t
(setq path (nreverse (tree-widget--locate-sub-directory
tree-widget-themes-directory
tree-widget-themes-load-path)))
(aset tree-widget--theme 1 (or path 'void))
path))))
(defconst tree-widget--cursors
'(
("guide" . arrow)
("no-guide" . arrow)
("end-guide" . arrow)
("handle" . arrow)
("no-handle" . arrow)
))
(defsubst tree-widget-set-image-properties (props)
"In current theme, set images properties to PROPS.
Does nothing if images properties have already been set for that
theme."
(or (aref tree-widget--theme 2)
(aset tree-widget--theme 2 props)))
(defsubst tree-widget-image-properties (name)
"Return the properties of image NAME in current theme.
Default global properties are provided for respectively Emacs and
XEmacs in the variables `tree-widget-image-properties-emacs', and
`tree-widget-image-properties-xemacs'."
(cons :pointer
(cons (or (cdr (assoc name tree-widget--cursors)) 'hand)
(tree-widget-set-image-properties
(if (featurep 'xemacs)
tree-widget-image-properties-xemacs
tree-widget-image-properties-emacs)))))
(defun tree-widget-lookup-image (name)
"Look up in current theme for an image with NAME.
Search first in current theme, then in parent themes (see also the
function `tree-widget-set-parent-theme').
Return the first image found having a supported format, or nil if not
found."
(catch 'found
(dolist (default-directory (tree-widget-themes-path))
(dolist (dir (aref tree-widget--theme 0))
(dolist (fmt (tree-widget-image-formats))
(dolist (ext (cdr fmt))
(setq file (expand-file-name (concat name ext) dir))
(and (file-readable-p file)
(file-regular-p file)
(throw 'found
(tree-widget-create-image
(car fmt) file
(tree-widget-image-properties name))))))))
nil))
(defun tree-widget-find-image (name)
"Find the image with NAME in current theme.
NAME is an image file name sans extension.
Return the image found, or nil if not found."
(when (tree-widget-use-image-p)
(tree-widget-set-theme (tree-widget-theme-name))
(let ((image (assoc name (aref tree-widget--theme 3))))
(if image
(cdr image)
(prog1
(setq image (tree-widget-lookup-image name))
(push (cons name image) (aref tree-widget--theme 3))))
)))
(defun tree-widget-button-click (event)
"Move to the position clicked on, and if it is a button, invoke it.
EVENT is the mouse event received."
(interactive "e")
(mouse-set-point event)
(let ((pos (widget-event-point event)))
(if (get-char-property pos 'button)
(widget-button-click event))))
(defvar tree-widget-button-keymap
(let ((km (make-sparse-keymap)))
(if (boundp 'widget-button-keymap)
(progn
(set-keymap-parent km widget-button-keymap)
(define-key km [button1] 'tree-widget-button-click))
(set-keymap-parent km widget-keymap)
(define-key km [down-mouse-1] 'tree-widget-button-click))
km)
"Keymap used inside node buttons.
Handle mouse button 1 click on buttons.")
(define-widget 'tree-widget-icon 'push-button
"Basic widget other tree-widget icons are derived from."
:format "%[%t%]"
:button-keymap tree-widget-button-keymap :keymap tree-widget-button-keymap :create 'tree-widget-icon-create
:action 'tree-widget-icon-action
:help-echo 'tree-widget-icon-help-echo
)
(define-widget 'tree-widget-open-icon 'tree-widget-icon
"Icon for an expanded tree-widget node."
:tag "[-]"
:glyph-name "open"
)
(define-widget 'tree-widget-empty-icon 'tree-widget-icon
"Icon for an expanded tree-widget node with no child."
:tag "[X]"
:glyph-name "empty"
)
(define-widget 'tree-widget-close-icon 'tree-widget-icon
"Icon for a collapsed tree-widget node."
:tag "[+]"
:glyph-name "close"
)
(define-widget 'tree-widget-leaf-icon 'tree-widget-icon
"Icon for a tree-widget leaf node."
:tag ""
:glyph-name "leaf"
:button-face 'default
)
(define-widget 'tree-widget-guide 'item
"Vertical guide line."
:tag " |"
:format "%t"
)
(define-widget 'tree-widget-end-guide 'item
"End of a vertical guide line."
:tag " `"
:format "%t"
)
(define-widget 'tree-widget-no-guide 'item
"Invisible vertical guide line."
:tag " "
:format "%t"
)
(define-widget 'tree-widget-handle 'item
"Horizontal guide line that joins a vertical guide line to a node."
:tag "-"
:format "%t"
)
(define-widget 'tree-widget-no-handle 'item
"Invisible handle."
:tag " "
:format "%t"
)
(define-widget 'tree-widget 'default
"Tree widget."
:format "%v"
:convert-widget 'tree-widget-convert-widget
:value-get 'widget-value-value-get
:value-delete 'widget-children-value-delete
:value-create 'tree-widget-value-create
:action 'tree-widget-action
:help-echo 'tree-widget-help-echo
:expander-p 'tree-widget-expander-p
:open-icon 'tree-widget-open-icon
:close-icon 'tree-widget-close-icon
:empty-icon 'tree-widget-empty-icon
:leaf-icon 'tree-widget-leaf-icon
:guide 'tree-widget-guide
:end-guide 'tree-widget-end-guide
:no-guide 'tree-widget-no-guide
:handle 'tree-widget-handle
:no-handle 'tree-widget-no-handle
)
(defun tree-widget-p (widget)
"Return non-nil if WIDGET is a tree-widget."
(let ((type (widget-type widget)))
(while (and type (not (eq type 'tree-widget)))
(setq type (widget-type (get type 'widget-type))))
(eq type 'tree-widget)))
(defun tree-widget-node (widget)
"Return WIDGET's :node child widget.
If not found, setup an `item' widget as default.
Signal an error if the :node widget is a tree-widget.
WIDGET is, or derives from, a tree-widget."
(let ((node (widget-get widget :node)))
(if node
(and (tree-widget-p node)
(error "Invalid tree-widget :node %S" node))
(setq node `(item :tag ,(or (widget-get widget :tag)
(widget-princ-to-string
(widget-value widget)))))
(widget-put widget :node node))
node))
(defun tree-widget-keep (arg widget)
"Save in ARG the WIDGET's properties specified by :keep."
(dolist (prop (widget-get widget :keep))
(widget-put arg prop (widget-get widget prop))))
(defun tree-widget-children-value-save (widget &optional args node)
"Save WIDGET children values.
WIDGET is, or derives from, a tree-widget.
Children properties and values are saved in ARGS if non-nil, else in
WIDGET's :args property value. Properties and values of the
WIDGET's :node sub-widget are saved in NODE if non-nil, else in
WIDGET's :node sub-widget."
(let ((args (cons (or node (widget-get widget :node))
(or args (widget-get widget :args))))
(children (widget-get widget :children))
arg child)
(while (and args children)
(setq arg (car args)
args (cdr args)
child (car children)
children (cdr children))
(if (tree-widget-p child)
(progn
(widget-put arg :args (widget-get child :args))
(widget-put arg :node (widget-get child :node))
(widget-put arg :open (widget-get child :open))
(when (widget-get child :open)
(widget-put arg :value (widget-value child))
(tree-widget-keep arg child)
(tree-widget-children-value-save
child (widget-get arg :args) (widget-get arg :node))))
(widget-put arg :value (widget-value child))
(tree-widget-keep arg child)))))
(defvar tree-widget-before-create-icon-functions nil
"Hooks run before to create a tree-widget icon.
Each function is passed the icon widget not yet created.
The value of the icon widget :node property is a tree :node widget or
a leaf node widget, not yet created.
This hook can be used to dynamically change properties of the icon and
associated node widgets. For example, to dynamically change the look
and feel of the tree-widget by changing the values of the :tag
and :glyph-name properties of the icon widget.
This hook should be local in the buffer setup to display widgets.")
(defun tree-widget-icon-create (icon)
"Create the ICON widget."
(run-hook-with-args 'tree-widget-before-create-icon-functions icon)
(widget-put icon :tag-glyph
(tree-widget-find-image (widget-get icon :glyph-name)))
(and (widget-get icon :tag-glyph)
(equal "" (or (widget-get icon :tag) ""))
(widget-put icon :tag " "))
(widget-default-create icon)
(insert-char ? 1)
(put-text-property
(1- (point)) (point)
'display (list 'space :width tree-widget-space-width)))
(defun tree-widget-convert-widget (widget)
"Convert :args as widget types in WIDGET."
(let ((tree (widget-types-convert-widget widget)))
(widget-put tree :expander (or (widget-get tree :expander)
(widget-get tree :dynargs)))
tree))
(defun tree-widget-value-create (tree)
"Create the TREE tree-widget."
(let* ((node (tree-widget-node tree))
(flags (widget-get tree :tree-widget--guide-flags))
(indent (widget-get tree :indent))
(widget-image-enable (tree-widget-use-image-p)) (widget-glyph-enable widget-image-enable) children buttons)
(and indent (not (widget-get tree :parent))
(insert-char ?\ indent))
(if (widget-get tree :open)
(let ((args (widget-get tree :args))
(guide (widget-get tree :guide))
(noguide (widget-get tree :no-guide))
(endguide (widget-get tree :end-guide))
(handle (widget-get tree :handle))
(nohandle (widget-get tree :no-handle))
(guidi (tree-widget-find-image "guide"))
(noguidi (tree-widget-find-image "no-guide"))
(endguidi (tree-widget-find-image "end-guide"))
(handli (tree-widget-find-image "handle"))
(nohandli (tree-widget-find-image "no-handle")))
(when (and (widget-get tree :expander)
(widget-apply tree :expander-p))
(setq args (mapcar 'widget-convert
(widget-apply tree :expander)))
(widget-put tree :args args))
(widget-put tree :node (widget-convert node))
(push (widget-create-child-and-convert
tree (widget-get tree (if args :open-icon :empty-icon))
:node (widget-get tree :node))
buttons)
(push (widget-create-child tree (widget-get tree :node))
children)
(widget-put (car buttons) :node (car children))
(while args
(setq node (car args)
args (cdr args))
(and indent (insert-char ?\ indent))
(dolist (f (reverse flags))
(widget-create-child-and-convert
tree (if f guide noguide)
:tag-glyph (if f guidi noguidi))
(widget-create-child-and-convert
tree nohandle :tag-glyph nohandli))
(widget-create-child-and-convert
tree (if args guide endguide)
:tag-glyph (if args guidi endguidi))
(widget-create-child-and-convert
tree handle :tag-glyph handli)
(if (tree-widget-p node)
(push (widget-create-child-and-convert
tree node :tree-widget--guide-flags
(cons (if args t) flags))
children)
(push (widget-create-child-and-convert
tree (widget-get tree :leaf-icon)
:node (setq node (widget-convert
node :tree-widget--guide-flags
(cons (if args t) flags)))
:tree-widget--leaf-flag t)
buttons)
(push (widget-create-child tree node) children)
(widget-put (car buttons) :node (car children)))))
(widget-put tree :node (widget-convert node))
(push (widget-create-child-and-convert
tree (widget-get tree :close-icon)
:node (widget-get tree :node))
buttons)
(push (widget-create-child tree (widget-get tree :node))
children)
(widget-put (car buttons) :node (car children)))
(widget-put tree :children (nreverse children))
(widget-put tree :buttons buttons)))
(defsubst tree-widget-leaf-node-icon-p (icon)
"Return non-nil if ICON is a leaf node icon.
That is, if its :node property value is a leaf node widget."
(widget-get icon :tree-widget--leaf-flag))
(defun tree-widget-icon-action (icon &optional event)
"Handle the ICON widget :action.
If ICON :node is a leaf node it handles the :action. The tree-widget
parent of ICON handles the :action otherwise.
Pass the received EVENT to :action."
(let ((node (widget-get icon (if (tree-widget-leaf-node-icon-p icon)
:node :parent))))
(widget-apply node :action event)))
(defun tree-widget-icon-help-echo (icon)
"Return the help-echo string of ICON.
If ICON :node is a leaf node it handles the :help-echo. The tree-widget
parent of ICON handles the :help-echo otherwise."
(let* ((node (widget-get icon (if (tree-widget-leaf-node-icon-p icon)
:node :parent)))
(help-echo (widget-get node :help-echo)))
(if (functionp help-echo)
(funcall help-echo node)
help-echo)))
(defvar tree-widget-after-toggle-functions nil
"Hooks run after toggling a tree-widget expansion.
Each function is passed a tree-widget. If the value of the :open
property is non-nil the tree has been expanded, else collapsed.
This hook should be local in the buffer setup to display widgets.")
(defun tree-widget-action (tree &optional event)
"Handle the :action of the TREE tree-widget.
That is, toggle expansion of the TREE tree-widget.
Ignore the EVENT argument."
(let ((open (not (widget-get tree :open))))
(or open
(tree-widget-children-value-save tree))
(widget-put tree :open open)
(widget-value-set tree open)
(run-hook-with-args 'tree-widget-after-toggle-functions tree)))
(defun tree-widget-help-echo (tree)
"Return the help-echo string of the TREE tree-widget."
(if (widget-get tree :open)
"Collapse node"
"Expand node"))
(defun tree-widget-expander-p (tree)
"Return non-nil if the TREE tree-widget :expander has to be called.
That is, if TREE :args is nil."
(null (widget-get tree :args)))
(provide 'tree-widget)