(defconst file-name-shadow-properties-custom-type
'(list
(checklist :inline t
(const :tag "Invisible"
:doc "Make shadowed part of filename invisible"
:format "%t%n%h"
:inline t
(invisible t intangible t))
(list :inline t
:format "%v"
:tag "Face"
:doc "Display shadowed part of filename using a different face"
(const :format "" face)
(face :value file-name-shadow))
(list :inline t
:format "%t: %v%h"
:tag "Brackets"
:doc " Surround shadowed part of filename with brackets"
(const :format "" before-string)
(string :format "%v" :size 4 :value "{")
(const :format "" after-string)
(string :format " and: %v" :value "} "))
(list :inline t
:format "%t: %v%n%h"
:tag "String"
:doc "Display a string instead of the shadowed part of filename"
(const :format "" display)
(string :format "%v" :size 15 :value "<...ignored...>"))
(const :tag "Avoid"
:doc "Try to keep cursor out of shadowed part of filename"
:format "%t%n%h"
:inline t
(field shadow)))
(repeat :inline t
:tag "Other Properties"
(list :inline t
:format "%v"
(symbol :tag "Property")
(sexp :tag "Value")))))
(defcustom file-name-shadow-properties
'(face file-name-shadow field shadow)
"Properties given to the `shadowed' part of a filename in the minibuffer.
Only used when `file-name-shadow-mode' is active.
If Emacs is not running under a window system,
`file-name-shadow-tty-properties' is used instead."
:type file-name-shadow-properties-custom-type
:group 'minibuffer
:version "22.1")
(defcustom file-name-shadow-tty-properties
'(before-string "{" after-string "} " field shadow)
"Properties given to the `shadowed' part of a filename in the minibuffer.
Only used when `file-name-shadow-mode' is active and Emacs
is not running under a window-system; if Emacs is running under a window
system, `file-name-shadow-properties' is used instead."
:type file-name-shadow-properties-custom-type
:group 'minibuffer
:version "22.1")
(defface file-name-shadow
'((t :inherit shadow))
"Face used by `file-name-shadow-mode' for the shadow."
:group 'minibuffer
:version "22.1")
(defvar rfn-eshadow-frobbed-minibufs nil)
(defvar rfn-eshadow-overlay)
(make-variable-buffer-local 'rfn-eshadow-overlay)
(defun rfn-eshadow-setup-minibuffer ()
"Set up a minibuffer for `file-name-shadow-mode'.
The prompt and initial input should already have been inserted."
(when minibuffer-completing-file-name
(setq rfn-eshadow-overlay
(make-overlay (minibuffer-prompt-end) (minibuffer-prompt-end)))
(let ((props
(if window-system
file-name-shadow-properties
file-name-shadow-tty-properties)))
(while props
(overlay-put rfn-eshadow-overlay (pop props) (pop props))))
(overlay-put rfn-eshadow-overlay 'evaporate t)
(add-to-list 'rfn-eshadow-frobbed-minibufs (current-buffer))
(add-hook 'post-command-hook #'rfn-eshadow-update-overlay nil t)))
(defsubst rfn-eshadow-sifn-equal (goal pos)
(equal goal (condition-case nil
(substitute-in-file-name
(buffer-substring-no-properties pos (point-max)))
(error nil))))
(defun rfn-eshadow-update-overlay ()
"Update `rfn-eshadow-overlay' to cover shadowed part of minibuffer input.
This is intended to be used as a minibuffer `post-command-hook' for
`file-name-shadow-mode'; the minibuffer should have already
been set up by `rfn-eshadow-setup-minibuffer'."
(condition-case nil
(let ((goal (substitute-in-file-name (minibuffer-contents)))
(mid (overlay-end rfn-eshadow-overlay))
(start (minibuffer-prompt-end))
(end (point-max)))
(unless
(and mid
(or (eq mid end)
(not (rfn-eshadow-sifn-equal goal (1+ mid))))
(or (eq mid start)
(rfn-eshadow-sifn-equal goal mid)))
(while (or (< (1+ start) end)
(if (and (< (1+ end) (point-max))
(rfn-eshadow-sifn-equal goal (1+ end)))
(setq start (1+ end) end (point-max))))
(setq mid (/ (+ start end) 2))
(if (rfn-eshadow-sifn-equal goal mid)
(setq start mid)
(setq end mid)))
(move-overlay rfn-eshadow-overlay (minibuffer-prompt-end) start)))
(error nil)))
(define-minor-mode file-name-shadow-mode
"Toggle File-Name Shadow mode.
When active, any part of a filename being read in the minibuffer
that would be ignored (because the result is passed through
`substitute-in-file-name') is given the properties in
`file-name-shadow-properties', which can be used to make
that portion dim, invisible, or otherwise less visually noticeable.
With prefix argument ARG, turn on if positive, otherwise off.
Returns non-nil if the new state is enabled."
:global t
:init-value t
:group 'minibuffer
:version "22.1"
(if file-name-shadow-mode
(add-hook 'minibuffer-setup-hook 'rfn-eshadow-setup-minibuffer)
(remove-hook 'minibuffer-setup-hook 'rfn-eshadow-setup-minibuffer)
(dolist (minibuf rfn-eshadow-frobbed-minibufs)
(with-current-buffer minibuf
(remove-hook 'post-command-hook #'rfn-eshadow-update-overlay t)))
(setq rfn-eshadow-frobbed-minibufs nil)))
(provide 'rfn-eshadow)